create windows user using Delphi

Question

I need to create new windows user as administrator using Delphi

Thanks

solved using net user but if there is any other solution plz post thanks — zac
– zac, Commented Mar 15, 2010 at 1:50

RRUZ · Accepted Answer · 2010-03-16 13:32:03Z

12

you can use the NetUserAdd and NetUserSetGroups functions declarated in the JEDI Headers.

see this simple sample.

program ProjectAddNewUser;

{$APPTYPE CONSOLE}

uses
  JclWin32,//Jedi Library
  Windows,
  SysUtils;


function CreateWinUser(const wServer, wUsername, wPassword, wGroup:WideString): Boolean;
var
  Buf       : USER_INFO_2;//Buf for the new user info
  Err       : NET_API_STATUS;
  ParmErr   : DWORD;
  GrpUsrInfo: USER_INFO_0;//Buf for the group
  wDummyStr : WideString;
begin
  wDummyStr:='';
  FillChar (Buf, SizeOf(USER_INFO_2), 0);
  with Buf do
  begin
    usri2_name      := PWideChar(wUsername);
    usri2_full_name := PWideChar(wUsername);//You can add a more descriptive name here
    usri2_password  := PWideChar(wPassword);
    usri2_comment   := PWideChar(wDummyStr);
    usri2_priv      := USER_PRIV_USER;
    usri2_flags     := UF_SCRIPT OR UF_DONT_EXPIRE_PASSWD;
    usri2_script_path := PWideChar(wDummyStr);
    usri2_home_dir    := PWideChar(wDummyStr);
    usri2_acct_expires:= TIMEQ_FOREVER;
  end;

  GrpUsrInfo.usri0_name:=PWideChar(wGroup);

  Err := NetUserAdd(PWideChar(wServer), 1, @Buf, @ParmErr);
  Result := (Err = NERR_SUCCESS);

  if Result then //NOw you must set the group for the new user
  begin
  Err := NetUserSetGroups(PWideChar(wServer),PWideChar(wGroup),0,@GrpUsrInfo,1);
  Result := (Err = NERR_SUCCESS);
  end;
end;

begin

  if CreateWinUser('localhost', 'MyNewUser','ThePassword','MyWindowsGroup') then
   Writeln('Ok')
  else
   Writeln('False');

  Readln;
end.

edited Mar 16, 2010 at 13:32

answered Mar 15, 2010 at 5:23

RRUZ

137k20 gold badges365 silver badges489 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Beto Neto Over a year ago

@RRUZ: i'm trying this code, but it fails on NetUserSetGroups with error 2220 (The group name could not be found). I'm trying to create a user with the "Adminitrators" group.

James L. Over a year ago

To make it work with the local Administrators group, I had to change three lines of code. GrpUserInfo: USER_INFO_0 became LOCALGROUP_MEMBERS_INFO_3. GrpUserInfo.usri0_name:=PWideChar(wGroup) became GrpUsrInfo.lgrmi3_domainandname := PWideChar(wUsername). And Err := NetUserSetGroups(PWideChar(wServer),PWideChar(wGroup),0,@GrpUsrInfo,1) became Err := NetLocalGroupAddMembers(PWideChar(wServer), PWideChar(wGroup), 3, @GrpUsrInfo, 1).

Igby Largeman · Accepted Answer · 2010-03-15 01:31:59Z

1

I think the API call you need is NetUserAdd.

First, check if Delphi provides a wrapper for this call. If not, you'll have to write your own. If you don't know how to make Windows API calls from Delphi, you have some more research to do.

answered Mar 15, 2010 at 1:31

Igby Largeman

16.8k3 gold badges62 silver badges88 bronze badges

1 Comment

user257111 Over a year ago

+1, I couldn't find it. I've got a feeling Delphi can call these functions directly, assuming they match the correct calling convention... like you I don't know.

Collectives™ on Stack Overflow

create windows user using Delphi

2 Answers 2

2 Comments

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related