Remove empty xml elements recursively with XSLT

Question

I am trying to recursively remove 'empty' elements (no children, no attribute or empty attribute) from the xml. This is the XSLT I have

<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[not(*) and
                       string-length(.)=0 and
                       (not(@*) or @*[string-length(.)=0])]">
    <xsl:apply-templates/>
</xsl:template>

This is the input XML. I expect this XML to be transformed to a empty string

<world>
    <country>
        <state>
            <city>
                <suburb1></suburb1>
                <suburb2></suburb2>
            </city>
        </state>
    </country>
</world>

But instead I am getting

<world>
    <country>
        <state/>
    </country>
</world>

Can anyone help? I've researched many threads in the forum but still no luck.

What is your input XML? And probably, whitespace is giving you problems, use normalize-space(). — Davio
– Davio, Commented Jul 16, 2014 at 8:59
HI Davio, just updated the question with the input XML to make it clearer. — James H
– James H, Commented Jul 16, 2014 at 10:36

michael.hor257k · Accepted Answer · 2014-07-16 12:04:26Z

7

The condition not(*) is false for any element that has children - regardless of what the children contain.

If you want to "prune" the tree of any branches that do not carry "fruit", try:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="*[descendant::text() or descendant-or-self::*/@*[string()]]">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="@*[string()]">
    <xsl:copy/>
</xsl:template>

</xsl:stylesheet>

edited Jul 16, 2014 at 12:04

answered Jul 16, 2014 at 9:40

michael.hor257k

118k6 gold badges36 silver badges55 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

James H Over a year ago

wow! that produces the exact result i need. Should have posted the question earlier saving days of investigation:) If you can do me a favor, can you explain in a bit more detail why it needs the second <template> that match="@*[string()]?

michael.hor257k Over a year ago

@JamesH It's required to copy (non-empty) attributes to the result tree.

Davio · Accepted Answer · 2014-07-16 09:01:44Z

1

So, fighting whitespace, try this:

<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[not(*) and
                       string-length(normalize-space(.))=0 and
                       (not(@*) or @*[string-length(normalize-space(.))=0])]">
    <xsl:apply-templates/>
</xsl:template>

answered Jul 16, 2014 at 9:01

Davio

4,7473 gold badges36 silver badges63 bronze badges

Collectives™ on Stack Overflow

Remove empty xml elements recursively with XSLT

2 Answers 2

2 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related