Async.Await not catching Task exception

Question

I have a Task that does not return anything. You can't do an Async.AwaitTask on such a Task, so you need to do an Async.AwaitIAsyncTask instead. Unfortunately this seems to just swallow any exceptions that the underlying Task throws out: -

TaskFactory().StartNew(Action(fun _ -> failwith "oops"))
|> Async.AwaitIAsyncResult
|> Async.Ignore
|> Async.RunSynchronously

// val it : unit = ()

On the other hand, AwaitTask correctly cascades the exception: -

TaskFactory().StartNew(fun _ -> failwith "oops"                               
                                5)
|> Async.AwaitTask
|> Async.Ignore
|> Async.RunSynchronously

// POP!

What's the best way of treating regular (non-generic) Tasks as Async yet still get propagation of exceptions?

desco · Accepted Answer · 2014-08-06 23:20:54Z

9

As an option that will properly handle cancellation:

open System.Threading.Tasks

module Async =
    let AwaitTask (t: Task) = 
        Async.FromContinuations(fun (s, e, c) ->
            t.ContinueWith(fun t -> 
                if t.IsCompleted then s()
                elif t.IsFaulted then e(t.Exception)
                else c(System.OperationCanceledException())
                )
            |> ignore
        )

answered Aug 6, 2014 at 23:20

desco

16.8k1 gold badge48 silver badges57 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

eulerfx Over a year ago

slight correction, the IsCompleted check must be made after the IsFaulted check because a fault is also considered completed.

N_A · Accepted Answer · 2014-08-06 20:50:16Z

2

From the Xamarin F# Shirt App (which I originally borrowed from Dave Thomas):

[<AutoOpen>]
module Async =
     let inline awaitPlainTask (task: Task) = 
        // rethrow exception from preceding task if it faulted
        let continuation (t : Task) = if t.IsFaulted then raise t.Exception
        task.ContinueWith continuation |> Async.AwaitTask

edited Aug 6, 2014 at 20:50

answered Aug 6, 2014 at 17:25

N_A

20k4 gold badges55 silver badges98 bronze badges

4 Comments

Daniel Over a year ago

Just let continuation (t : Task) = if t.IsFaulted then raise t.Exception is probably clearer.

N_A Over a year ago

@Daniel Feel free to make it better. :-) I'm not possessive of my answers!

Martin Over a year ago

Think I first saw this here: theburningmonk.com/2012/10/…

desco Over a year ago

downsides: cancellation is not handled properly, reraising exception drops the stacktrace

Collectives™ on Stack Overflow

Async.Await not catching Task exception

2 Answers 2

1 Comment

4 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

4 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related