Force racket to accept recursive variable definition as a recursive function definition

Question

For fun I've created a bunch of functions in Racket that create and combine other functions.

Now I've defined a recursive function in terms of them:

(define (my-flatten2 struct)
  ((<?> pair?
       (<+> append <m>
            (</> map my-flatten2)
            (<Y> car cdr))
       list)
   struct))

I tried this first, but it didn't work (it gave me a can't reference identifier before its definition error):

(define my-flatten-error
  (<?> pair?
       (<+> append <m>
            (</> map my-flatten-error)
            (<Y> car cdr))
       list))

Can anyone explain why it didn't work, and whether or not there is a way to fix it.

For the record

<+> is compose
<Y> is create a function that applies a list of functions to one arg
</> is partially apply
<?> is choice

John Clements · Accepted Answer · 2014-09-08 18:58:27Z

3

Racket is an eager language; it evaluates arguments before passing them. So, your code does not work for the same reason that

(define p (add1 p))

doesn't work.

In this case, assuming that my-flatten error does turn out to be a function, it might be fairly easy to solve your problem just by delaying the evaluation of my-flatten-error:

(define my-flatten-error
  (<?> pair?
       (<+> append <m>
            (</> map (lambda args 
                       (apply my-flatten-error args)))
            (<Y> car cdr))
       list))

You can also hide the lambda using a macro:

(define-syntax delay-fn
  (syntax-rules ()
    [(delay-fn f) (lambda args (apply f args))]))


(define my-flatten-error
  (<?> pair?
       (<+> append <m>
            (</> map (delay-fn my-flatten-error))
            (<Y> car cdr))
       list))

... if you find that visually more pleasing.

answered Sep 8, 2014 at 18:58

John Clements

17.3k3 gold badges39 silver badges53 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

jgon Over a year ago

Awesome, that makes a lot of sense

Collectives™ on Stack Overflow

Force racket to accept recursive variable definition as a recursive function definition

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related