batch file read from file toa array variable

Question

I got a list in text file (names.txt) like this:

This is documment no....... etc

Sent : 20.04.2013

Details for ............. etc

Num : 1

Name : John

Surname : White

Born : 09/17/1993

Num : 2

Name : Peter

Surname : Tosh

Born : 09/14/1991

............. .............

This documment can not............

@echo off 

setlocal enabledelayedexpansion

for /F "delims=" %%a in (C:\tmp\names.txt) do (
    set /A count1+=1
    set "array!count1!=%%a"
)
set /A count1-=1

set /A count2=1
set /A count3=2

for /L %%i in (4,4,%count1%) do (
    set /A count2+=4
    set /A count3+=4
    echo !array%%i!  !array%count2%!  !array%count3%!
)

I want to list them like

Num : 1 Name :John Surname : White

Num : 2 Name :Peter Surname : Tosh

Num : 3 Name :Me Surname : Myself

..............

Just 3 data in one row but doesnt work. What I'm doing wrong?

Aacini · Accepted Answer · 2014-09-14 04:16:11Z

1

The Batch file below solve the problem as stated; it does not require any array:

@echo off
setlocal EnableDelayedExpansion

set "Surname="
for /F "tokens=1,2 delims=: " %%a in (C:\tmp\names.txt) do (
   set "%%a=%%b"
   if defined Surname (
      echo Num : !Num! Name : !Name! Surname : !Surname!
      set "Surname="
   )
)

Output:

Num : 1 Name : John Surname : White
Num : 2 Name : Peter Surname : Tosh

edited Sep 14, 2014 at 4:16

answered Sep 14, 2014 at 4:06

Aacini

67.7k12 gold badges74 silver badges114 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

foxidrive · Accepted Answer · 2014-09-13 15:15:19Z

0

Test this to see if it does what you need:

@echo off 
for /F "usebackq delims=" %%a in ("C:\tmp\names.txt") do (
  set /p "=%%a "<nul
  echo "%%a" |find /i "Born" >nul && echo(
)
pause

answered Sep 13, 2014 at 15:15

foxidrive

41.4k11 gold badges61 silver badges71 bronze badges

Comments

Torqane · Accepted Answer · 2014-09-14 04:00:27Z

0

How about this:

echo off
setlocal enabledelayedexpansion

set xSurname=
for /f "tokens=1,2 delims=: " %%a in (%TEMP%\names.txt) do (
    if /i '%%a'=='Num' set xNum=%%b
    if /i '%%a'=='Name' set xName=%%b
    if /i '%%a'=='Surname' set xSurname=%%b
    if not '!xSurname!'=='' (
        echo Num: !xNum! Name: !xName! Surname: !xSurname!
        set xSurname=
    )
)

Makes assumptions that the Surname line ends a block (Born: is ignored) and outputs what it has gathered to that point in the block. Note I changed the path to %TEMP% vs C:\tmp. You probably would do better using %TEMP% as that's set by the operating system.

answered Sep 14, 2014 at 4:00

Torqane

1565 bronze badges

Collectives™ on Stack Overflow

batch file read from file toa array variable

3 Answers 3

Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related