Batch file - read two lines into two separate variable within one for loop

Question

I have a text file (list.txt) which is a list filenames that can be simplified as below:
a
b
c
d

I need a "for" loop that does something like below:

set variable1=a  
set variable2=b
do something with variable1 & 2, lets say variable1 + variable2>>output.txt

then restart the loop from the second line:
set variable1=b
set variable2=c
perform the addition>>output.txt

then from the third line:
set variable1=c
set variable2=d etc..
and keep going until the end of my list.txt

It seems batch file has difficulty when handling multiple lines of data within a loop.
Could someone kindly shed some light on this? Thanks in advance.

Have you written a code or a batch that does this already, but does not work as it should be? — Juniar
– Juniar, Commented Sep 25, 2014 at 1:28

Magoo · Accepted Answer · 2014-09-25 02:01:32Z

1

@ECHO OFF
SETLOCAL
SET "var1="
SET "var2="
FOR /f %%a IN (q26028954.txt) DO (
 CALL SET "var1=%%var2%%"
 SET "var2=%%a"
 IF DEFINED var1 (
  SET /a total=var1+var2
  CALL ECHO %%var1%% + %%var2%% = %%total%%
  )
)

GOTO :EOF

Where q26028954.txt contains

Yields

1 + 4 = 5
4 + 7 = 11
7 + 11 = 18

could also be used with delayedexpansion. Note the use of the set /a total - the run-time, not the parse-time values are applied to the calculation.

answered Sep 25, 2014 at 2:01

Magoo

80.8k8 gold badges68 silver badges92 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

npocmaka · Accepted Answer · 2014-09-25 01:36:15Z

1

@echo off

setlocal disableDelayedExpansion

set "file_to_process=c:\some.txt"
set "line="
for /f "usebackq tokens=* delims=" %%# in ("%file_to_process%") do (
    setlocal enableDelayedExpansion
    if "!line!" NEQ "" (
        echo do something with !line! and %%#
    )
    endlocal & set "line=%%#"

)

endlocal

Change the path to your file.

answered Sep 25, 2014 at 1:36

npocmaka

57.8k19 gold badges162 silver badges199 bronze badges

2 Comments

Alan Over a year ago

Thank you too npocmaka. I don't quite understand your method as I don't see the two variables. Will give it another go when I got chance. :)

npocmaka Over a year ago

@Alan - Do you mean it does not work? Because it works for me (and should be pretty fast too as it does not use subroutines)

Collectives™ on Stack Overflow

Batch file - read two lines into two separate variable within one for loop

2 Answers 2

Comments

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related