Remove a null character (Shell Script)

To filter filenames that end with ., since filenames are the whole input line in find's output, you could use

sed '/\.$/d'

Where \. matches a literal dot and $ matches the end of the line.

However, I think I'd do the whole thing in awk. Since sorting does not appear to be necessary:

EDIT: Found a nicer way to do it with awk and find's -printf action.

find . -type f -printf '%f\n' | awk -F. '!/\./ || $NF == "" { ++count["noext"]; next } { ++count[$NF] } END { for(k in count) { print k " " count[k] } }'

Here we pass -printf '%f\n' to find to make it print only the file name without the preceding directory, which makes it much easier to work with for our purposes -- this way there's no need to worry about periods in directory names (such as /etc/somethingorother.d). The field separator is '.', the awk code is

!/\./ || $NF == "" {        # if the line (the filename) does not contain
                            # a period or there's nothing after the last .
  ++count["noext"]          # increment the "noext" counter
                            # note that this will be collated with files that
                            # have ".noext" as filename extension. see below.
  next                      # go to the next line
}
{                           # in all other lines
  ++count[$NF]              # increment the counter for the file extension
}
END {                       # in the very end:
  for(k in count) {         # print the counters.
    print count[k] " " k
  }
}

Note that this way, if there is a file "foo.noext", it will be counted among the files without a filename extension. If this is a worry, use a special counter for files without an extension -- either apart from the array or with a key that cannot be a filename extension (such as one that includes a . or the empty string).