How can I extract part of a string based on a pattern using Windows CMD?

Question

I have an input let's say:

DummyString-v1.0.0

and I would like to extract everything after v to get: 1.0.0

How can I achieve this in CMD?

Io-oI · Accepted Answer · 2021-03-21 13:01:29Z

9

@ECHO OFF
SETLOCAL
SET "string=DummyString-v1.0.0"
SET "string=%string:*v=%"
ECHO %string%
GOTO :EOF

where the :*substring=replacementstring syntax is applied meaning "every character form the start of the variable (string) up to the substring (v) is replaced by the replacement string (nothing).

edited Mar 21, 2021 at 13:01

Io-oI

2,6053 gold badges27 silver badges32 bronze badges

answered Jan 23, 2015 at 16:10

Magoo

80.8k8 gold badges68 silver badges92 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

MaYaN Over a year ago

You are a STAR!, very elegant solution. Just one thing though, if input has another v then this will break so I had to also add the - to address the problem. so I modified it to be: SET "string=%string:*-v=%"

npocmaka · Accepted Answer · 2015-01-23 16:23:29Z

1

@echo off

call :split "DummyString-v1.0.0" "v"
echo %last_part%

exit /b 0

:split

set "string=%~1"
set "splitter=%~2"

setlocal EnableDelayedExpansion
set LF=^


rem ** Two empty lines are required
echo off
for %%L in ("!LF!") DO (
    for /f "delims=" %%R in ("!splitter!") do ( 
        set "var=!string:%%R=%%L!"      
    )
)
for /f "delims=" %%P in (""!var!"") DO set "last_part=%%~P"
endlocal &(
  set last_part=%last_part%
  exit /b 0
)

edited Jan 23, 2015 at 16:23

answered Jan 23, 2015 at 16:13

npocmaka

57.8k19 gold badges162 silver badges199 bronze badges

Collectives™ on Stack Overflow

How can I extract part of a string based on a pattern using Windows CMD?

2 Answers 2

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related