1

I am making a game from a batch file and one of the inputs can accept any character (~!@#$%^&*()`) and any other. Is there any way to look for any character other than numbers and use the GOTO command? This is my script so far:

set /p guess=
echo "%guess%"|findstr /L "[a-z][A-Z]~`!@#$%^&*()-_=+\^|^^;:"',<.>/?*"
if %errorlevel% == 0 goto Invalid_Number
if %guess% == %number% goto Correct
... everything else here ...

:Invalid_Number
echo Invalid Number. Input must be a number
pause

Is there any way to make this work, all it says is Access Denied, I am testing this on a school computer though, it might not work.

Improve this question

3 Answers 3

Reset to default
4 
:ask    
    set /p "guess=?" || goto :ask

    setlocal enabledelayedexpansion 
    for /f "delims=0123456789" %%a in ("!guess!") do set "guess="
    endlocal & set "guess=%guess%"

    if not defined guess (
        echo invalid input
        goto ask
    )

    echo valid input

The basic idea behind the test is to use the numbers as delimiters in a for /f command, so they are removed from the input. If anything remains it is not a number and the code in the do clause is executed.

The delayedexpansion is enabled/disabled to handle problematic characters (specially double quotes) that could be typed in the input field.

Improve this answer
Sign up to request clarification or add additional context in comments.

2 Comments

Thank you so much, there is a problem, If the guess var includes & it says & was unexpted, can you help?
@JacobRocks12, i can not reproduce the indicated behaviour. For me, the posted code works with all input, including &.
3

Put this at the bottom of your script:

:isInt <str>
for /f "delims=0123456789" %%a in ("%1") do exit /b 1
exit /b 0

Then to invoke it, do

call :isInt %guess% && success || fail

Here's a more complete example:

@echo off
setlocal

set /a rand = %RANDOM% %% 10 + 1

:begin
set /P "guess=Guess a number between 1 and 10: "

call :isInt %guess% || goto invalid

if %guess% gtr 0 if %guess% lss 11 (
    if %guess% equ %rand% (
        echo Lucky guess!
        exit /b
    ) else (
        echo Oooh, so close.  Try again.
        goto begin
    )
)

:invalid
echo Please enter a valid integer between 1 and 10.
goto begin

:isInt <str>
for /f "delims=0123456789" %%a in ("%1") do exit /b 1
exit /b 0

This is the same basic idea as MC ND's solution, but instead of using the for statement to unset %guess%, it sets %errorlevel% and stops looping at the first non-numeric character. This makes it infinitesimally more efficient. :)

And with either success or fail, I like to use conditional execution (the && and || stuff).

Improve this answer

3 Comments

Nice, but : 1) While the call makes the code more organized (and yes, i usually code that way) the call command is SLOW and makes the full process less efficient. 2) Have you tried to input a single "? The delayed expansion used in the in clause was included to avoid this kind of problems on input validation.
Good points :) Is call really slower than goto? I suppose it makes sense, since call invokes a child runtime. Still faster than findstr or similar, though.
call makes aditional tests not present in goto , but obviously it is faster not to call nor goto to do the test. But call does not execute a child runtime. The batch file is executed inside a "batch context" in memory. The call command creates a new "batch context structure" in memory (independtly of calling another batch or calling a label in current batch), and is executed inside the same running cmd instance after swapping pointers to the new "context". On end of called code, its "context" is discarded and the caller "context" regains control
3

May I suggest you a different, better approach? Instead of read any line and then check if it contains a number, your program may directly read a number, so the checking is not necessary. The way to do that is emulating SET /P command via a subroutine. This way, you may add additional constraints to the input, like read a maximum number of digits, for example.

@echo off

rem Read a number emulating SET /P command
rem Antonio Perez Ayala

setlocal
rem Define the following variable before call InputNumber subroutine
set "thisFile=%~F0"

call :InputNumber number="Enter a number of up to 5 digits: " 5
echo Number read: %number%
goto :EOF


:InputNumber var="prompt" [digits]

setlocal EnableDelayedExpansion

rem Initialize variables
if "%~3" equ "" (set numDigits=9) else set "numDigits=%3"
set "digits=0123456789"
for /F %%a in ('copy /Z "%thisFile%" NUL') do set "CR=%%a"
for /F %%a in ('echo prompt $H ^| cmd') do set "BS=%%a"

rem Show the prompt and start reading
set /P "=%~2" < NUL
set "input="
set i=0

:nextKey
   set "key="
   for /F "delims=" %%a in ('xcopy /W "%thisFile%" "%thisFile%" 2^>NUL') do if not defined key set "key=%%a"

   rem If key is CR: terminate input
   if "!key:~-1!" equ "!CR!" goto endRead

   rem If key is BS: delete last char, if any
   set "key=!key:~-1!"
   if "!key!" equ "!BS!" (
      if %i% gtr 0 (
         set /P "=!BS! !BS!" < NUL
         set "input=%input:~0,-1%"
         set /A i-=1
      )
      goto nextKey
   )

   rem If key is not a digit: ignore it
   if "!digits:%key%=!" equ "%digits%" goto nextKey

   rem If can not accept more digits: ignore it
   if %i% equ %numDigits% goto nextKey

   rem Else: show and accept the digit
   set /P "=%key%" < NUL
   set "input=%input%%key%"
   set /A i+=1

goto nextKey

:endRead
echo/
endlocal & set "%~1=%input%"
exit /B

You may also add any other processing to the input line, like show asterisks instead of digits, etc. For a large example on this topic, see this post

Improve this answer

Comments

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.