How to select distinct values from XML document using XPATH?

Question

How can I select only distinct elements for the XML document using XPATH?I've tried to use the 'distinct-values' function but it didn't work for some reason..

The XML is similar to the following:

<catalog>

<product>
<size>12</size>
<price>1000</price>
<rating>1</rating>
</product>

<product>
<size>10</size>
<price>1000</price>
<rating>1</rating>
<year>2010</year>
</product>

</catalog>

So what I want to get is the list of distinct children of all the product elements.In the given example it would be - size,price,rating,year My xpath was something like : distinct-values(catalog/product/*)

distinct-values function used for only one value for and inline content or attribute content.What do you mean by distinct children exactly?Is it different element names like size,price,rating,not the values ? — Myra
– Myra, Commented May 20, 2010 at 7:45
Sorry..yeah,exactly.I want to get the list of all the distinct children element names — Alex
– Alex, Commented May 20, 2010 at 7:47
Excellent Question (+1). See my answer for solutions in XPath 2.0, and XSLT 1.0. — Dimitre Novatchev
– Dimitre Novatchev, Commented May 20, 2010 at 13:24

Dimitre Novatchev · Accepted Answer · 2010-05-20 13:23:40Z

In XPath 2.0:

distinct-values(/*/*/*/name(.))

In XPath 1.0 this cannot be produced with a single XPath expression.

Using XSLT 1.0:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:template match="/">
   <xsl:for-each select=
   "/*/*/*[not(../following::*/*
                       [not(name() = name(current()))]
               )
           ]">
     <xsl:value-of select="concat(name(), ' ')"/>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the provided XML document, the wanted result is produced:

size price rating year

A more efficient XSLT 1.0 transformation, using keys:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:key name="kpchildByName"
  match="product/*" use="name()"/>

 <xsl:template match="/">
   <xsl:for-each select=
   "/*/*/*
         [generate-id()
         =
          generate-id(key('kpchildByName', name())[1])
          ]">
     <xsl:value-of select="concat(name(), ' ')"/>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

Chris Wallace · Accepted Answer · 2010-05-20 08:34:14Z

7

You need the distinct values of the element names - something like:

distinct-values($catalog/product/*/name(.))

answered May 20, 2010 at 8:34

Chris Wallace

5253 silver badges11 bronze badges

Comments

Marco · Accepted Answer · 2015-06-29 14:30:29Z

4

distinct-values() is available in XPath 2.0. Are you using that?

If distinct-values() is not available, the standard way of getting distinct values is to use not(@result = preceding:: @result) to get unique @result. It will give you the first occurrence only.

edited Jun 29, 2015 at 14:30

Marco

24.2k13 gold badges81 silver badges132 bronze badges

answered May 20, 2010 at 7:49

341008

10.3k14 gold badges58 silver badges85 bronze badges

2 Comments

Alex Over a year ago

I'm not sure which XPATH version I've got:) How can I find out about that?

Anonymoose Over a year ago

That would only work if the list is sorted on your result

Collectives™ on Stack Overflow

How to select distinct values from XML document using XPATH?

3 Answers 3

Comments

Comments

2 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related