perl while loop iterates through a variable.

Question

This little snippet is from the first chapter of the LWP perl oreilly book. This line

$count++ while $catalog =~ m/Perl/gi;

perplexes me

I do not understand how the while statement iterates through the lines in the $catalog variable to find the matched, I don't even know how to explain what that line does in english much less perl

#!/usr/bin/perl -w
use strict ;
use LWP::Simple ;
my $catalog = get("http://www.oreilly.com/catalog");
my $count = 0;
$count++ while $catalog =~ m/Perl/gi;
print "$count\n";

so I have tried writing it out long hand to no avail.

#!/usr/bin/perl -w
use strict ;
use LWP::Simple ;
my $catalog = get("http://www.oreilly.com/catalog");


open( my $fh_catalog ,"<" , $catalog) || die "cant open $!";
while (<$fh_catalog>) {
    print $_ ;
    sleep 1;
}

I even tried

#!/usr/bin/perl -w
use strict ;
use LWP::Simple ;
my $catalog = get("http://www.oreilly.com/catalog");

while (<$catalog>) {
    print $_ ;
    sleep 1;
}

ikegami · Accepted Answer · 2015-04-12 05:46:56Z

4

$catalog contains the string <!DOCTYPE HTML PUB[...][newline][newline]<html>[...].

Your first snippet fails because $catalog doesn't contain a file name.

Your second snippet fails because $catalog doesn't contain a file handle.

When a match operator with the /g modifier is used scalar context, it searches from where the last search left off.

The analog would be

use Time::HiRes qw( sleep );  # Support sleeping fractions of seconds.
$| = 1;  # Turn off STDOUT's output buffering.
for my $i (0..length($content)-1) {
   print(substr($content, $i, 1));
   sleep 0.1;
}

Let's use a simpler string as an example.

my $s = "a000a000a000";
++$count while $s =~ /a/g;

Here's what happens:

The match operator is executed. It finds the first a, sets pos($s) = 1;, and returns true.
The loop body is entered, and $count is incremented.
The match operator is executed. It behaves as if the string started as pos($s) (1), finds the second a, sets pos($s) = 5;, and returns true.
The loop body is entered, and $count is incremented.
The match operator is executed. It behaves as if the string started as pos($s) (5), finds the third a, sets pos($s) = 9;, and returns true.
The loop body is entered, and $count is incremented.
The match operator is executed. It behaves as if the string started as pos($s) (9), fails to find a match, clears pos($s), and returns false. The loops exits.

Nothing changes if some of the characters of the string are newlines.

edited Apr 12, 2015 at 5:46

answered Apr 12, 2015 at 5:40

ikegami

391k17 gold badges291 silver badges555 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

capser Over a year ago

thank you Ikegami - I knew global meant search the whole document, but did not understand how it searched globally. watching the analog version print out is the coolest.

Collectives™ on Stack Overflow

perl while loop iterates through a variable.

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related