F# working with while loop

Question

I have a datareader and i want to return collection of rows from it, after reading books for like a day i am not able to find out best way to do it in f#. I can do it normal C# way in F# but that is not why i am using f#

Here is what i am trying to achieve

let values =
    while reader.Read() do
        yield reader.GetString(0), reader.GetInt64(1)

Above is how i am trying to do

all values get collected into values, which could be dictinary or tuples or any collection
yield can't be used in while loop but that is what i am trying to do

What could be the best way to achieve this

gradbot · Accepted Answer · 2010-06-05 15:48:27Z

17

F# also provides list comprehension for arrays and sequences.

let records_as_list = 
    [
        while reader.Read() 
            do yield (reader.GetString(0), reader.GetInt64(1)) 
    ]

let records_as_array = 
    [|
        while reader.Read() 
            do yield (reader.GetString(0), reader.GetInt64(1)) 
    |]

let records_as_sequence = 
    seq {
        while reader.Read() 
            do yield (reader.GetString(0), reader.GetInt64(1)) 
    }

F# has a convenient dictionary function built in called dict

let records_as_IDictionary = dict records_as_sequence

answered Jun 5, 2010 at 15:48

gradbot

13.9k5 gold badges41 silver badges69 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Mau · Accepted Answer · 2010-06-05 15:07:30Z

7

You can use sequence expressions to implement enumerators:

let records = seq { while reader.NextResult() do yield (reader.GetString(0), reader.GetInt64(1)) }

If you need more than two fields, you can yield maps of column index (or name) -> field values (untested code):

let dbSchema = reader.GetSchemaTable()

let makeMap (rdr : IDataReader) (schema : DataTable) =
    schema.Columns |> Seq.cast<DataColumn> |> Seq.map (fun col -> (col.ColumnName, rdr.[col.ColumnName])) |> Map.ofSeq

let records = seq { while reader.NextResult() do yield (makeMap reader dbSchema) }

answered Jun 5, 2010 at 15:07

Mau

14.5k2 gold badges33 silver badges53 bronze badges

2 Comments

mamu Over a year ago

Problem with seq is that it does lazy loading so when you want to read it in this case reader would be closed

Mau Over a year ago

Easily fixed by appending |> Seq.toList to the last row to materialise the collection.

Yin Zhu · Accepted Answer · 2010-06-05 15:31:33Z

3

For this kind of task, I'd like to first transfer the input into a sequence of strings.

.Net 4.0 provides ReadLines, the type of its return value is seq<string>:

   open System.IO
   let readLinesSeq = File.ReadLines

In lower versions of .Net, one needs to implement this function:

   let readLines filePath = seq {
    use sr = new StreamReader (filePath)
    while not sr.EndOfStream do
     yield sr.ReadLine ()
   }

answered Jun 5, 2010 at 15:31

Yin Zhu

17.1k13 gold badges79 silver badges118 bronze badges

1 Comment

Joel Mueller Over a year ago

Yes, the basic idea is the same.

Joel Mueller · Accepted Answer · 2010-06-05 17:11:13Z

2

I might approach this problem more generically by adding an extension property to IDataReader that turns any datareader into a seq<IDataRecord>...

[<AutoOpen>]
module DataReaderEx =
    open System.Data

    type IDataReader with
        member this.toSeq =
            seq { while this.Read() do yield this :> IDataRecord }

This would allow you to use ordinary functions from the Seq module on any datareader:

reader.toSeq
|> Seq.map (fun row -> row.GetString(0), row.GetInt64(1))

answered Jun 5, 2010 at 17:11

Joel Mueller

28.8k9 gold badges67 silver badges89 bronze badges

Comments

Mau · Accepted Answer · 2010-06-05 15:36:38Z

0

Well we are not talking about files here, however, in earlier .NET versions you can do (with small files):

reader.ReadToEnd().Split(System.Environment.NewLine.ToCharArray())

Where reader is a TextReader.

answered Jun 5, 2010 at 15:36

Mau

14.5k2 gold badges33 silver badges53 bronze badges

2 Comments

Yin Zhu Over a year ago

If the file is big, reading all the content and splitting should be avoided.

Joel Mueller Over a year ago

In this question, reader is actually an IDataReader, not a TextReader

Collectives™ on Stack Overflow

F# working with while loop

5 Answers 5

Comments

2 Comments

1 Comment

Comments

2 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

5 Answers 5

Comments

2 Comments

1 Comment

Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related