Remove item from array

Question

How do you remove an item in the middle of an array? I tried this:

Public Sub RemoveArrayElement(AryVar() As Object, ByVal RemoveWhich As Long)
Dim byteLen As Byte    
byteLen = 4

If RemoveWhich < UBound(AryVar) Then
    CopyMemory ByVal VarPtr(AryVar(RemoveWhich)), ByVal _
        VarPtr(AryVar(RemoveWhich + 1)), (byteLen) * _
        (UBound(AryVar) - RemoveWhich)
End If

If UBound(AryVar) = LBound(AryVar) Then
    Erase AryVar
Else
    ReDim Preserve AryVar(UBound(AryVar) - 1)
End If
End Sub

But when I retrieve item from aryvar, it returns Nothing.

Hrqls · Accepted Answer · 2015-05-21 08:02:47Z

and another approach :

'1 form with:
'  1 command button: name=Command1

Option Explicit

Private Sub Command1_Click()
  Dim intIndex As Integer
  'dim an array with undefined boundaries
  Dim intArray() As Integer
  'set boundaries
  ReDim intArray(10) As Integer
  'fill array with values
  For intIndex = 0 To 10
    intArray(intIndex) = intIndex * intIndex
  Next intIndex
  'show the data from the initial array
  ShowArray intArray
  'remove the 6th item (index=5)
  intArray = RemoveItem(5, intArray)
  'show the data of the resulting array (with the 6h item removed)
  ShowArray intArray
End Sub

Private Function RemoveItem(intItem As Integer, intSrc() As Integer) As Integer()
  Dim intIndex As Integer
  Dim intDest() As Integer
  Dim intLBound As Integer, intUBound As Integer
  'find the boundaries of the source array
  intLBound = LBound(intSrc)
  intUBound = UBound(intSrc)
  'set boundaries for the resulting array
  ReDim intDest(intLBound To intUBound - 1) As Integer
  'copy items which remain
  For intIndex = intLBound To intItem - 1
    intDest(intIndex) = intSrc(intIndex)
  Next intIndex
  'skip the removed item
  'and copy the remaining items, with destination index-1
  For intIndex = intItem + 1 To intUBound
    intDest(intIndex - 1) = intSrc(intIndex)
  Next intIndex
  'return the result
  RemoveItem = intDest
End Function

Private Sub ShowArray(intArray() As Integer)
  Dim intIndex As Integer
  'print all items to the form to show their value
  For intIndex = LBound(intArray) To UBound(intArray)
    Print "Item " & CStr(intIndex) & " : " & CStr(intArray(intIndex))
  Next intIndex
  'print an empty line to separate the arrays in displaying
  Print
End Sub

The differences :

return the array instead of passing byref
using a temporary array which is dimmed to the right size instead of redim preserve at the end
copy the items which keep the same index, and only move the ones after the removed item

Anish Sharma · Accepted Answer · 2015-05-22 13:56:25Z

1

Well This code snippet might help you.

Dim remove_place As Integer
Dim ar() As Integer
Dim n As Integer
n = 10
ReDim ar(n)                     'Initial size of an array
remove_place = Val(Text1.Text)  'This is the position to be deleted
For i = remove_place To n - 1
ar(i) = ar(i + 1)               'This loop will shift array position one    place   to the left. This way the number at your position will be replaced by the next number.
Next
ReDim Preserve ar(n - 1)        'I guess you know what it means.

Place it under any event procedure.

edited May 22, 2015 at 13:56

answered May 22, 2015 at 13:21

Anish Sharma

5253 silver badges17 bronze badges

2 Comments

tjvg1991 Over a year ago

why is there a text box? I have not text box

Anish Sharma Over a year ago

Well it was just a demonstration. I used text box to take the position from user via the text box. You can take up any other alternative. That depends upon you. This program was just to demonstrate the "Remove" algorithm.

Andrew Alderson · Accepted Answer · 2019-07-25 23:28:43Z

1

A bit of a different approach then the one you're taking above, but couldn't you just shuffle all the values down and shrink the array afterwards?

For example:

Public Sub RemoveArrayElement(AryVar() As Object, ByVal RemoveWhich As Long)
    If UBound(AryVar) > 0 Then
        Dim i As Integer
        For i = LBound(AryVar) To UBound(AryVar) - 1
            If i >= removeWhich Then
                    AryVar(i) = AryVar(i + 1)
            End If
        Next
        ReDim Preserve AryVar(UBound(AryVar) - 1)
    End If
End Sub

edited Jul 25, 2019 at 23:28

answered May 21, 2015 at 4:47

Andrew Alderson

90312 silver badges20 bronze badges

3 Comments

C-Pound Guru Over a year ago

This looks like vb.net. Question is tagged vb6.

tjvg1991 Over a year ago

@C-PoundGuru it is indeed vb6

Shafeek Over a year ago

"For i As Integer" is not supported in vb6

Collectives™ on Stack Overflow

Remove item from array

3 Answers 3

Comments

2 Comments

3 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

2 Comments

3 Comments

Your Answer

Sign up or log in

Post as a guest

Related