How to set a variable with an environment variable read from a text file

Question

I've created the following config file which contains parameters to be used by a batch file:

File winscp.conf:

folder    %appData%\winscp
version   5.7.4
visit     http://sourceforge.net/projects/winscp/files/WinSCP/
download  http://sourceforge.net/projects/winscp/files/WinSCP/5.7.4/winscp574.zip

Batch file (get.bat):

@echo off
setlocal

@if not exist "%1" (
    echo Config file not found in "%1"
    exit /B
)
@for /f "tokens=1,2 delims= " %%A in (%1) do (
    set %%A=%%B
)

mkdir %folder%

When I call the batch file like this:

get.bat winscp.conf

I get a sub-folder %appData%\winscp created in the current folder, something like this:

c:\Temp\%appData%\winscp

While what I want is a winscp folder created in the Windows app data folder, something like this:

C:\Users\Caffe\AppData\Roaming\winscp

I think there's something wrong with the statement set %%A=%%B, since if I change it to set %%A=%appData%\winscp I do get the folder created the way I want.

Community · Accepted Answer · 2017-05-23 12:14:09Z

I just summarize the answers of wOxxOm and JosefZ with adding some small improvements.

@echo off
setlocal EnableExtensions
set "ConfigFile=%~1"

if "%ConfigFile%" == "" (
    echo %~nx0 must be called with name of configuration file
    echo as first parameter, for example: %~nx0 winscp.conf
    goto EndBatch
)

if not exist "%ConfigFile%" (
    echo Config file "%ConfigFile%" not found.
    goto EndBatch
)

set "folder="

for /F "usebackq tokens=1*" %%A in ("%ConfigFile%") do call set "%%A=%%B"

if "%folder%" == "" (
    echo Option "folder" not defined in config file "%ConfigFile%".
    goto EndBatch
)

mkdir "%folder%" 2>nul

:EndBatch
endlocal

For better reading what first argument passed to the batch file should be, the parameter is immediately assigned to an environment variable without the surrounding quotes which must be used if configuration file name with or without path contains anywhere at least 1 space character.

Next a check is made if batch file was called at all with a parameter.

After FOR loop it is verified if the configuration file really contained an entry for folder.

And creation of directory is made with using quotes because folder path can contain spaces, and with redirecting any error message to device nul, i.e. suppress the error message output if directory exists already.

woxxom · Accepted Answer · 2015-07-23 17:27:36Z

2

The variables inside tokens should be expanded prior to the assignment by adding call:

call set %%A=%%B

answered Jul 23, 2015 at 17:27

woxxom

75.2k15 gold badges161 silver badges164 bronze badges

1 Comment

woxxom Over a year ago

BTW, if your values will ever have spaces here's a more reliable way to parse: @for /f "tokens=1*" %%A in (%1) do, %%A = the first word before space, %%B = the rest.

JosefZ · Accepted Answer · 2015-07-23 17:31:34Z

1

With next changes in your code:

call set instead of set
for /f "tokens=1,* instead of for /f "tokens=1,2

then next code snippet should work:

@ECHO OFF
SETLOCAL enableextensions
if not exist "%1" (
    echo Config file not found in "%1"
    exit /B
)
for /f "tokens=1,* delims= " %%A in (%1) do (
    call set "%%A=%%B"
)
mkdir %folder%

answered Jul 23, 2015 at 17:31

JosefZ

30.5k6 gold badges52 silver badges96 bronze badges

Collectives™ on Stack Overflow

How to set a variable with an environment variable read from a text file

3 Answers 3

Comments

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related