Add multiple keys to an anonymous hash in Perl

Question

I have a hash that holds for each record an anonymous hash with 2 elements: an array and a hash. I want to initialize this subsidiary hash with a list of keys.

I know hash slices can be used when you use a normal hash (not a ref) and use both a key list and values list.

My code is like this

my %records;
my $key = "key1";
my @states = ( "state1", "state2", "state3" );

$records{$key} = {
    numbers => [],
    states  => %{@states} #This is wrong !
};

EDIT (marked as duplicate): This question asks how to add multiple keys to an anonymous hash.

Slices are cool, but you don't have to use them everywhere. Just do my $states = { ... }; $records{$key} = { states => $states }; — ThisSuitIsBlackNot
– ThisSuitIsBlackNot, Commented Aug 28, 2015 at 20:49
I could have sworn somebody asked this before, but the closest I could find was Anonymous Hash Slices - syntax? — ThisSuitIsBlackNot
– ThisSuitIsBlackNot, Commented Aug 28, 2015 at 21:14
Shorter is not always better. Generally you should shoot for readability rather than brevity. — ThisSuitIsBlackNot
– ThisSuitIsBlackNot, Commented Aug 28, 2015 at 21:16
You should show what you want %records to look like. It's puzzling that you have only keys for your hash and no values — Borodin
– Borodin, Commented Aug 28, 2015 at 21:45

Borodin · Accepted Answer · 2015-08-28 21:51:21Z

It's puzzling that you have only keys for your hash and no values. This code will set the value of each element of $records{$key}{states} to undef

my %records;
my $key = "key1";
my @states = ( "state1", "state2", "state3" );

$records{$key} = {
    numbers => [],
    states  => { map { ( $_ => undef ) } @states },
};

But it would be clearer to build a proper hash temporarily and assign a reference to it to the data structure. I've enclosed the entire assignment process in its own block so that I can declare a temporary lexical hash %states

{
    my %states;
    @states{@states} = ();

    $records{$key} = {
        numbers => [],
        states  => \%states,
    };
}

But note that it's generally better if hash elements don't exist at all rather than create them with undefined values. There is no need to preallocate the elements of a hash like this, just leave it empty like you did with the array

$records{$key} = {
    numbers => [],
    states  => {},
}

Collectives™ on Stack Overflow

Add multiple keys to an anonymous hash in Perl

1 Answer 1

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related