Custom sorting with custom ordering

Looking at your code, the sCustomList looks like a string type variable and not a variant array. My success with custom sort lists has been to create a new one every time and use the highest index number to reference it.

Sub custom_sort()
    Dim vCustom_Sort As Variant, rr As Long

    vCustom_Sort = Array("green", "yellow", "red", Chr(42))
    Application.AddCustomList ListArray:=vCustom_Sort

    With Worksheets("Sheet2")    '<~~ set this properly!
        .Sort.SortFields.Clear
        rr = .Cells(Rows.Count, "G").End(xlUp).Row
        With .Range("A3:T" & rr)
            'use this to presort one or more secondary fields before the primary custom sort
            '.Cells.Sort Key1:=.Columns(18), Order1:=xlAscending, _
                        Key2:=.Columns(1), Order2:=xlDescending, _
                        Orientation:=xlTopToBottom, Header:=xlYes
            .Cells.Sort Key1:=.Columns(7), Order1:=xlAscending, _
                        Orientation:=xlTopToBottom, Header:=xlYes, MatchCase:=False, _
                        OrderCustom:=Application.CustomListCount + 1

        End With
        .Sort.SortFields.Clear
    End With

End Sub

There is a twist between .Cells.Sort.SortFields.Add and .Cells.Sort that usually generates some confusion. The .SortFields.Add method uses a CustomOrder:= parameter and the Range.Sort method uses a OrderCustom:= parameter. The two are most definitely NOT the same but often get used interchangeably with disastrous results.

If you use the SortFields object, you don't have to refer to custom lists: It should be obvious below where to change the various range references. I also added an alphabetical sort on one of the columns other than G

Option Explicit
Sub TrafficLightSort()
    Dim WS As Worksheet
    Dim rSortRange As Range, rSortKey As Range
    Const sSortOrder As String = "Green,Yellow,Red"

Set WS = Worksheets("sheet1")
With WS
    Set rSortRange = Range("E1", .Cells(.Rows.Count, "E").End(xlUp)).Resize(columnsize:=3)
    Set rSortKey = rSortRange.Columns(3)

    With .Sort.SortFields
        .Clear
        .Add Key:=rSortKey, _
            SortOn:=xlSortOnValues, _
            Order:=xlAscending, _
            CustomOrder:=sSortOrder
        .Add Key:=rSortRange.Columns(1), _
            SortOn:=xlSortOnValues, _
            Order:=xlAscending
    End With

    With .Sort
        .SetRange rSortRange
        .Header = xlNo
        .MatchCase = False
        .Orientation = xlTopToBottom
        .Apply
    End With
End With

End Sub

I would recommend adding a table with an explicit sorting order to your worksheet (green = 1, yellow = 2, etc). Then add a column to your sorting range that uses a lookup function to return the sorting value and use VBA to run a standard sort based on that column. This will leave you with VBA code that is easier for developers to read, allows Excel users who don't read VBA to see your sort order, and avoids burying hardcoded values deep in you macro.