Batch: Array index returns blank

Question

In this piece of code I'm trying to make a list fit the screen in WinPE by alternating into two columns. But when I put !modelsvar[%increment%]:~20! in the echo it returns only ~20. Strange because !modelsvar[%%D]:~20! works fine. I've tried many variations of ! and % but no luck. Anyone know if there's is a specific rule that I'm missing?

I have setlocal enabledelayedexpansion enabled

set modelsx=%counter%
set /a counter=0

for /l %%D in (1,2,%modelsx%) do (
set /a counter+=1
set /a increment=!counter!+1
ECHO !counter!. !modelsvar[%%D]:~20!      !increment!. !modelsvar[%increment%]:~20!
set /a counter+=1
)

Community · Accepted Answer · 2017-05-23 10:27:07Z

1

for /l %%D in (1,2,%modelsx%) do (
   set /a counter+=1
   set /a increment=counter+1
   for %%X in (!increment!) do (
      ECHO !counter!. !modelsvar[%%D]:~20!      !increment!. !modelsvar[%%X]:~20!
   )
   set /a counter+=1
)

Further details at Arrays, linked lists and other data structures in cmd.exe (batch) script

edited May 23, 2017 at 10:27

CommunityBot

11 silver badge

answered Oct 14, 2015 at 15:27

Aacini

67.7k12 gold badges74 silver badges114 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Einar Þórir Árnason Over a year ago

That works. Thank you. I suspected it had something to do with process order but i didn't think i could echo from two for loops in one line alternatively.

aschipfl · Accepted Answer · 2015-10-14 15:39:29Z

1

You're expanding increment immediately within ECHO, that is like %increment%, so the returned value is the one before the for loop executes.

Here is another work-around:

set modelsx=%counter%
set /a counter=0

for /l %%D in (1,2,%modelsx%) do (
    set /a counter+=1
    set /a increment=!counter!+1
    call ECHO !counter!. !modelsvar[%%D]:~20!      !increment!. %%modelsvar[!increment!]:~20%%
    set /a counter+=1
)

answered Oct 14, 2015 at 15:39

aschipfl

35.3k12 gold badges62 silver badges106 bronze badges

Collectives™ on Stack Overflow

Batch: Array index returns blank

2 Answers 2

1 Comment

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related