Set/get variables in loop in xslt or another solution

No, it's not possible, because XSLT is a functional language. It doesn't have mutable variables and it doesn't have loops. (xsl:for-each is not a loop, it is a mapping expression, which applies the same operation to every item in a sequence, conceptually in parallel rather than sequentially).

The way to solve your problem (as is often the case in functional languages) is with recursion: specifically, a technique I call "sibling recursion".

From the tr element, process the first td child:

<xsl:template match="tr">
 <xsl:apply-templates select="td[1]" mode="sib">
  <xsl:with-param name="col" select="1"/>
 </xsl:apply-templates>
</xsl:template>

From the td element, process the next sibling td child:

<xsl:template match="td" mode="sib">
 <xsl:param name="col"/>
 <zc col="$col"/>
 <xsl:apply-templates select="following-sibling::td[1]" mode="sib">
  <xsl:with-param name="col">
    <xsl:choose>
      <xsl:when test="@colspan">
        <xsl:value-of select="$col + @colspan"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$col + 1"/>
      </xsl:otherwise>
    </xsl:choose>
   </xsl:with-param>
 </xsl:apply-templates>
</xsl:template>

(It's much less verbose with XSLT 2.0!)