Delete certain line in text file using batch

Question

I have a txt file . I want to delete line 4 and line 5 only.

Before

Line1  
Line2  
Line3  
Line4 (need to delete)  
Line5 (need to delete)  
Line6

After

Line1  
Line2  
Line3  
Line6

How do you select lines 4 and 5? By content or by position?

Magoo
– Magoo

2015-11-10 05:36:28 +00:00
Commented Nov 10, 2015 at 5:36 — Magoo
– Magoo, Commented Nov 10, 2015 at 5:36

Aacini · Accepted Answer · 2015-11-10 14:23:32Z

1

@echo off
setlocal EnableDelayedExpansion

call :CopyLines < input.txt > output.txt
move /Y output.txt input.txt
goto :EOF


:CopyLines

rem Copy lines 1, 2 and 3
for /L %%i in (1,1,3) do (
   set "line="
   set /P "line="
   echo(!line!
)

rem Omit lines 4 and 5
for /L %%i in (4,1,5) do set /P "line="

rem Copy the rest
findstr "^"

exit /B

answered Nov 10, 2015 at 14:23

Aacini

67.7k12 gold badges74 silver badges114 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

prudviraj · Accepted Answer · 2015-11-10 06:12:05Z

0

Try below code which would do exactly what you require :

@echo off
cls
setlocal EnableDelayedExpansion
set /a count=0
if exist neww.txt (del /s /q neww.txt) 

for /f "tokens=*" %%a in (onee.txt) do (
set /a count+=1

if !count! EQU 4 (
echo do nothing
)else if !count! EQU 5 (
echo do nothing
)else (
echo %%a>>neww.txt
)
)

move /y neww.txt onee.txt

answered Nov 10, 2015 at 6:12

prudviraj

3,8042 gold badges18 silver badges23 bronze badges

Collectives™ on Stack Overflow

Delete certain line in text file using batch

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related