Using eval with awk expression in gnuplot script

Question

I am trying to plot a parametric expression in a gnuplot script which its coefficient are stored in the last row of text file. To do so, firstly I tried this:

plot "<awk 'END{print $1"*cos(t)*cos("$2")-"$3"*sin(t)*sin("$4"), "$1"*cos(t)*sin("$2")+"$3"*sin(t)*cos("$4")"}' manip_file.csv"

but gnuplot says undefined variable: t. So next I tried the following:

plotCMD = 'awk 'END{print "plot " $1"*cos(t)*cos("$2")-"$3"*sin(t)*sin("$4"), "$1"*cos(t)*sin("$2")+"$3"*sin(t)*cos("$4")"}' manip_file.csv'
eval(plotCMD)

But this time gnuplot says ';' expected. If I run the awk command in the command line it gives me a correct equation which gnuplot has not problem plotting it. Hence it is not a problem of missing some single/double quotations. Trying to escape the dollar signs (\$1) didn't solve the problem as well. Any thoughts?

You are probably looking for How to use shell variables in awk script — fedorqui
– fedorqui, Commented Nov 16, 2015 at 13:28

Christoph · Accepted Answer · 2015-11-16 13:44:28Z

6

You are completely mixing gnuplot and awk syntax together. Here is a solution with gnuplot:

# 1. Get the last row of your text file
p = system('tail -1 manip_file.csv')

# 2. Get the four parameters, assuming they are white-space separated
p1 = word(p, 1)*1.0
p2 = word(p, 2)*1.0
p3 = word(p, 3)*1.0
p4 = word(p, 4)*1.0

# 3. Define the functions
x(t) = p1*cos(t)*cos(p2) - p3 * sin(t)*sin(p4)
y(t) = p1*cos(t)*sin(p2)+p3*sin(t)*cos(p4)

# 4. Plot them
set parametric
plot x(t), y(t)

answered Nov 16, 2015 at 13:44

Christoph

48.7k8 gold badges94 silver badges198 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Pouya Over a year ago

Thank you very much. Quick question: Why have you multiplied word(p, i) by 1.0? Is it sort of a hack for typecasting?

Christoph Over a year ago

Yes. Probably it would also work without this multiplication, since you multiply the parameters again inside the functions. But I wanted to point out this "typecast"

Collectives™ on Stack Overflow

Using eval with awk expression in gnuplot script

1 Answer 1

2 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

2 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related