Shell script to replace string and add new line

Question

I am new to shell scripting and have a request to modify multiple files. I have
the input as below

#this is line1 for [email protected]        
test line 2  
test line 3  
this is line4 for [email protected]  
test line 5  
this is line6 for [email protected]

and need output like

#this is line1 for [email protected]   
test line 2  
test line 3   
##this is line4 for [email protected]  
this is line4 for [email protected]  
test line 5   
##this is line6 for [email protected]**  
this is line6 for [email protected]

i tried the below sed command, but not able to get the required output. It is not skipping the #line and appends it.

sed -e "/abc.com/{h;s/^/##/P;x;G; /^#/!s/abc.com/xyz.com/;}" file1

is there something i am missing???

Please help and any other suggestions would also be much appreciated.

Regards, Santosh

Can you more clearly show what your desired output is? Are the * part of the input and part of the desired output? Nothing in your example sed command skips lines with leading # for the first bit of work. — Etan Reisner
– Etan Reisner, Commented Jan 5, 2016 at 19:57

glenn jackman · Accepted Answer · 2016-01-06 01:54:21Z

1

This seems to be what you want

sed '/^[^#].*@abc.com/ {h; s/^/##/; p; g; s/abc.com/xyz.com/;}'

The equivalent awk:

awk '/^[^#].*abc.com/ {print "##" $0; sub(/abc.com/, "xyz.com")};1'

Pedantically, the dot should be escaped: abc\.com

edited Jan 6, 2016 at 1:54

answered Jan 5, 2016 at 20:13

glenn jackman

249k42 gold badges233 silver badges362 bronze badges

Sign up to request clarification or add additional context in comments.

10 Comments

Santosh Over a year ago

i tried this command but it gives me error sed: Function /^[^#].*@abc.com/ {h; s/^/##/; p; g; s/abc.com/xyz.com/} cannot be parsed.

glenn jackman Over a year ago

Hmm, worked for me with GNU sed. Try adding a semicolon before the ending brace.

Santosh Over a year ago

Thanks Glenn. It worked perfectly well after adding the semicolan

Santosh Over a year ago

How to do case insensitive sed, i mean like how to replace ABC.com XYZ.com in the search

glenn jackman Over a year ago

With GNU sed, you would use s/.../.../i, Otherwise you may have to s/[aA][bB][cC]\.com/xyx.com/

|

Lee HoYo · Accepted Answer · 2016-01-06 12:10:17Z

0

sed '
    /^#/n; 
    /.*abc.com/{
        h;  # hold this line to HOLD SPACE
        s/abc.com/xyz.com/;  # modify
        x;  # exchange PATTERN with HOLD
        s/^/##/;  
        G;  # get
    }
'

answered Jan 6, 2016 at 12:10

Lee HoYo

1,2679 silver badges9 bronze badges

Comments

potong · Accepted Answer · 2016-01-06 14:44:32Z

0

This might work for you (GNU sed):

sed 's/^\([^#].*\)abc\.com/##&\n\1xyz.com/' file

Only substitute lines which do not begin with a # and containd abc.com. The RHS of the substitution consists of the original line prepended by ## and a second line where the string abc.com is replace by xyz.com.

edited Jan 6, 2016 at 14:44

answered Jan 6, 2016 at 7:15

potong

59.3k6 gold badges55 silver badges92 bronze badges

Collectives™ on Stack Overflow

Shell script to replace string and add new line

3 Answers 3

10 Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

10 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related