Skip first node and iterate from second node of a xml in VBS

Question

Anyone could suggest the best way to skip first occurrence of first node of a XML and start iteration from second node. In the example below, I want to skip first occurrence of node "word" and start Iterating form second occurrence of node "word". Thanks in advance.

<words>
 <word>
  <name>Vowel</name>
 </word>
 <word>
  <value>a</value>
 </word>
 <word>
  <value>Vowel</value>
 </word>
</words>

Ekkehard.Horner · Accepted Answer · 2016-02-12 11:42:51Z

1

The child nodes of a node are collected in its childNodes collection. To skip nodes you need to loop over the childNodes by number/index instead of the more frequent For Each approach. In code:

Option Explicit

Dim sXPath : sXPath    = "/words"
Dim oXDoc  : Set oXDoc = CreateObject("Msxml2.DOMDocument.6.0")
oXDoc.setProperty "SelectionLanguage", "XPath"
oXDoc.async = False
oXDoc.load "35359922.xml"

If 0 = oXDoc.ParseError Then
   Dim ndWords : Set ndWords = oXDoc.selectSingleNode(sXPath)
   If ndWords Is Nothing Then
      WScript.Echo "|", sXPath, "| not found"
   Else
      WScript.Echo "found " & ndWords.childNodes.length & " nodes."
      Dim i
      For i = 1 To ndWords.childNodes.length - 1
          WScript.Echo i, ndWords.childNodes(i).text
      Next
   End If

Else
   WScript.Echo oXDoc.ParseError.Reason
End If

output:

cscript 35359922.vbs
found 3 nodes.
1 a
2 Vowel

answered Feb 12, 2016 at 11:42

Ekkehard.Horner

38.8k2 gold badges50 silver badges101 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Jyotish Singh Over a year ago

Appreciate your solution, Thanks.

Collectives™ on Stack Overflow

Skip first node and iterate from second node of a xml in VBS

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related