extract value from an array in xslt

Question

I have variable 'temperatureQualifier' whose type is array. I need to read that array variable and extract each value from the array and use it in my XSLT.

Sample Input XML is

<document>
<item>
    <gtin>1000909090</gtin>
    <flex>
        <attrGroupMany name="tradeItemTemperatureInformation">
            <row>
                <attr name="temperatureQualifier">[10, 20, 30, 40]</attr>
            </row>

        </attrGroupMany>
    </flex>
</item>
</document>

Desired Output XML should be

<?xml version="1.0" encoding="UTF-8"?>
<CatalogItem>
<RelationshipData>
  <Relationship>
     <RelationType>Item_Master_TRADEITEM_TEMPERATURE_MVL</RelationType>
     <RelatedItems>
        <Attribute name="code">
           <Value>10</Value>
        </Attribute>
         <Attribute name="code">
           <Value>20</Value>
        </Attribute>
         <Attribute name="code">
           <Value>30</Value>
        </Attribute>
         <Attribute name="code">
           <Value>40</Value>
        </Attribute>
     </RelatedItems>
  </Relationship>
</RelationshipData>
</CatalogItem>

I am using the below XSLT but it is giving me all values in 1 node only.

<xsl:stylesheet 
version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output indent="yes"/>


<xsl:template match="document"> 
    <CatalogItem>
        <RelationshipData>
            <Relationship>
                <RelationType>Item_Master_TRADEITEM_TEMPERATURE_MVL</RelationType>  
                <RelatedItems>      


                    <xsl:for-each select="item/flex/attrGroupMany[@name ='tradeItemTemperatureInformation']/row">                       

                        <Attribute name="code">
                            <Value>
                                <xsl:value-of select="attr[@name='temperatureQualifier']"/>
                            </Value>
                        </Attribute>


                    </xsl:for-each>
                </RelatedItems>
            </Relationship>
        </RelationshipData>
    </CatalogItem>

</xsl:template> 

</xsl:stylesheet>

Note: Number of value in array can be 1 or more than 1. Example for single value array is [10]

Example for multie value array is [10, 20, 30, 40]

You've tagged this xslt-2.0 but are you actually able to use an XSLT 2.0 processor? If so, you would be able to make use of the tokenize function. — Tim C
– Tim C, Commented Mar 23, 2016 at 11:10

hr_117 · Accepted Answer · 2016-03-23 11:25:06Z

With XST 1.0 you can use a recursive split:

<xsl:template name="split">
 <xsl:param name="str" select="."/>
  <xsl:choose>
    <xsl:when test="contains($str, ',')">
       <Attribute name="code">
       <Value>
        <xsl:value-of select="normalize-space(substring-before($str, ','))"/>
      </Value>
      </Attribute>
      <xsl:call-template name="split">
        <xsl:with-param name="str" select="substring-after($str, ',')"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <Attribute name="code">
         <Value>
          <xsl:value-of select="$str"/>
        </Value>
      </Attribute>
    </xsl:otherwise>
  </xsl:choose>

</xsl:template>

And call it:

          <xsl:call-template name="split">
            <xsl:with-param name="str" select="substring-before(
                                               substring-after(
                                               attr[@name='temperatureQualifier'], '[' )
                                               ,']' )"/>
          </xsl:call-template>

Martin Honnen · Accepted Answer · 2016-03-23 11:30:35Z

0

Using the latest version of Saxon you could try XSLT 3.0 and

                    <xsl:for-each
                        select="item/flex/attrGroupMany[@name = 'tradeItemTemperatureInformation']/row/attr[@name = 'temperatureQualifier']/json-to-xml(.)//*:number">

                        <Attribute name="code">
                            <Value>
                                <xsl:value-of select="."/>
                            </Value>
                        </Attribute>


                    </xsl:for-each>

answered Mar 23, 2016 at 11:30

Martin Honnen

169k6 gold badges100 silver badges122 bronze badges

1 Comment

Victor Over a year ago

Sorry!! I forgot to maintain that it was for v1.0. Anyways this solution can help others.. Thanks.

Collectives™ on Stack Overflow

extract value from an array in xslt

2 Answers 2

Comments

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related