Haskell - have a function return an empty character

Question

I'm trying to create a function that drops every n'th element from a string.

dropEvery :: String -> Int -> String
dropEvery str n = map (\(char, indx) -> if indx `mod` n /= 0 then char else ' ') (zip str [1..])

Right now it simply replaces every n'th element with a space, but what am I supposed to put after the "else" if I want it to return an "empty char". I understand that such a thing doesn't exist in Haskell so the question is - how am I supposed to tell Haskell to not return anything and just move on to the next char?

bheklilr · Accepted Answer · 2016-04-11 16:46:45Z

7

You can't do this with just map, by definition it can't change the length of the collection it's applied to. However, you can get this to work without too many changes by switching to concatMap. This function requires the your function that you're mapping return a list, then it concatenates all the results together. All you'd need to do is

dropEvery str n =
    concatMap (\(char, indx) -> if indx `mod` n /= 0 then [char] else []) (zip str [1..])

answered Apr 11, 2016 at 16:46

bheklilr

54.2k6 gold badges112 silver badges167 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Raul Špilev Over a year ago

I did attempt to put "[]" after "else", but of course ended up getting type errors. concatMap is a good idea.

bheklilr Over a year ago

@RaulŠpilev The problem comes from assuming that there is something called an "empty Char". This would be like an "empty Int" or an "empty Bool", you can have an Int that is 0, but not one that doesn't have a value at all (not counting undefined). In order to have emptiness, you need a container. Strings are containers, since they're simply a list of Chars, so by having a function (Char, Int) -> [Char], you can use concatMap over a [(Char, Int)] to get out a [Char]`.

Lee · Accepted Answer · 2016-04-11 16:46:29Z

5

map preserves the structure of the list, while your operations modifies it by removing elements. This means you can't use map, but you can use mapMaybe which allows you to provide a function which returns Nothing for elements you want to remove from the output:

import Data.Maybe (mapMaybe)
dropEvery str n = mapMaybe (\(char, indx) -> if indx `mod` n /= 0 then Just(char) else Nothing) (zip str [1..])

answered Apr 11, 2016 at 16:46

Lee

145k20 gold badges243 silver badges292 bronze badges

2 Comments

bheklilr Over a year ago

I'd have to run some tests to be sure but this might be a more efficient solution than mine

Raul Špilev Over a year ago

This is pretty much exactly what I was looking for. I was thinking about using "Nothing" and "Just (char)", but wasn't sure how without getting "Couldn't match expected type" errors."mapMaybe" solves this. Also, now I understand how the map function works much better.Thanks.

dfeuer · Accepted Answer · 2016-04-11 17:30:20Z

3

You can do this without mod. I'm going to flip the order of the arguments to make this more idiomatic.

dropEvery :: Int -> [a] -> [a]
dropEvery n xs = map fst . filter ((/= n) . snd) $ zip xs (cycle [1..n])

If speed is critical, it would likely be most efficient to use this technique with explicit recursion or foldr. Something like this:

dropEvery n xs = foldr go (`seq` []) xs n where
  go _ r 1 = r n
  go x r k = x : r (k - 1)

edited Apr 11, 2016 at 17:30

answered Apr 11, 2016 at 17:04

dfeuer

48.8k5 gold badges69 silver badges171 bronze badges

Collectives™ on Stack Overflow

Haskell - have a function return an empty character

3 Answers 3

2 Comments

2 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

2 Comments

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related