How to apply for loop for comma separated arguments passed to the script in batch?

Question

I have a list of folders listed below:

C:\Program Files
C:\temp
C:\John Snow

I have to pass comma separated arguments to scripts like given below:

script.bat C:\Program Files,C:\temp,C:\John Snow

After passing to the script I need to filter out comma separated argument and apply for each loop and echo the argument value and execute dir command to list files in that director

you need to iterate arguments in the script.bat or you want to call script .bat with each of the items? — npocmaka
– npocmaka, Commented May 19, 2016 at 11:15
I need to iterate arguments in script.bat . And inside for loop, I need to execute DIR command for each arguments — Thejesh PR
– Thejesh PR, Commented May 19, 2016 at 12:03
You can pass the list of arguments surrounded by double quotes and access this list with %1 inside the script. From there you can iterate using a for /f command giving "," as delimiter. Check here. — Daniel Luz
– Daniel Luz, Commented May 19, 2016 at 12:15
@Danial Luz, If you could write it for me it will be better because I'm not that good in batch scripting.. — Thejesh PR
– Thejesh PR, Commented May 19, 2016 at 12:26

JosefZ · Accepted Answer · 2016-05-19 12:43:25Z

1

@ECHO OFF
SETLOCAL EnableExtensions
set "_params=%*"
if not defined _params (
  echo %~nx0: nothing to do
  pause
  exit /B
)
set "_params=%_params:,=","%"
for %%G in ("%_params%") do (
  echo dir "%%~G"
)

Output

==> 37321331.bat
37321331.bat: nothing to do
Press any key to continue . . .

==> 37321331.bat C:\Program Files,C:\temp,C:\John Snow
dir "C:\Program Files"
dir "C:\temp"
dir "C:\John Snow"

==>

Above script requires some elaborating: it would fail if some argument is enclosed in a pair of double quotes:

==> 37321331.bat C:\Program Files,C:\temp,"C:\John Snow"
dir "C:\Program Files"
dir "C:\temp"
dir ""C:\John"
dir "Snow"""

Edit. Use next code snippet to fix it: set "_params=%_params:"=%" would remove all " double quotes from supplied string.

set "_params=%_params:"=%"
set "_params=%_params:,=","%"
for %%G in ("%_params%") do (
  echo dir "%%~G"
)

Resources (required reading, incomplete):

(command reference) An A-Z Index of the Windows CMD command line
(additional particularities) Windows CMD Shell Command Line Syntax
(%~G, %* etc. special page) Command Line arguments (Parameters)
(%variable:StrToFind=NewStr% etc.) Variable Edit/Replace

edited May 19, 2016 at 12:43

answered May 19, 2016 at 12:22

JosefZ

30.5k6 gold badges52 silver badges96 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

Thejesh PR Over a year ago

For Me its coming like this: c:\batch>com.bat "c:\Program Files,c:\John Snow" dir ""c:\Program" dir "Files","c:\John" dir "Snow"""

JosefZ Over a year ago

@ThejeshPR This behaviour I have admonished already: please read entire answer.

JosefZ Over a year ago

@ThejeshPR fixed for double quotes. Please consider marking most helpful answer as accepted. See this page for an explanation of why this is important.

npocmaka · Accepted Answer · 2016-05-19 12:32:52Z

0

set "args=%*"
set "args=%args:,=","%"
for %%# in ("%args%") do (
  dir "%%~#"
)

try this.

edited May 19, 2016 at 12:32

answered May 19, 2016 at 12:20

npocmaka

57.8k19 gold badges162 silver badges199 bronze badges

3 Comments

Thejesh PR Over a year ago

%%# value is coming NULL, its just listing current directory files.

Thejesh PR Over a year ago

Its coming Like this(i have use ech dir "%%~#"): c:\batch>com.bat "c:\Program Files,c:\John Snow" dir ""c:\Program" dir "Files","c:\John" dir "Snow""" Its taking space as delimiter.

npocmaka Over a year ago

@ThejeshPR are you passing the line surrounded by double quotes?

Collectives™ on Stack Overflow

How to apply for loop for comma separated arguments passed to the script in batch?

2 Answers 2

3 Comments

3 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

3 Comments

Your Answer

Sign up or log in

Post as a guest

Related