IF ELSE problem COMMAND BATCH

Question

I have problem about IF ELSE in Command Batch script...

In Notepad:
Code:

:CHECKACCOUNT
if /I "%user%"=="insertusername" ( GOTO :ACCOUNT ) ELSE ( GOTO :CHECKPASSACCT )

:CHECKPASSACCT
if /I "%pass%"=="insertpassword" ( GOTO :ACCOUNT ) ELSE ( GOTO :COUNTER )

In COMMAND:
Code:

( was unexpected at this time.

FULL Script Code:

@echo off

::SETTINGS:::::::::::::::::::::::
set filetxt =userpass.txt
set log=logfile.log
set timer=900
::set default = true
::set user = 0
::set pass = 0
:::::::::::::::::::::::::::::::::


:STARTER
ECHO.>>%log%
ECHO ========START========>>%log%
SetLocal EnableDelayedExpansion
Set n=
Set _InputFile=%filetxt%
For /F "tokens=*" %%I IN (%_InputFile%) DO (
Set /a n+=1
Set acct!n!=%%I
)
set router_ip=%acct1%
set user=%acct2%
set pass=%acct3%
GOTO :CHECKFILE1


:CHECKFILE1
CLS
IF EXIST curl.exe ( GOTO :CHECKFILE2 ) else (
ECHO ERROR: curl.exe was not found.>>%log%
ECHO ERROR: curl.exe was not found.
ECHO.
ECHO.
GOTO :PAUSEEXIT
)

:CHECKFILE2
CLS
IF EXIST sleep.exe ( GOTO :CHECKACCOUNT ) else (
ECHO ERROR: sleep.exe was not found.>>%log%
ECHO ERROR: sleep.exe was not found.
ECHO.
ECHO.
GOTO :PAUSEEXIT
)

:CHECKACCOUNT
if /I "%user%"=="insertusername" GOTO ACCOUNT
GOTO CHECKPASSACCT

:CHECKPASSACCT
if /I "%pass%"=="insertpassword" GOTO ACCOUNT
GOTO COUNTER

:ACCOUNT
CLS
::if %default% = true ( GOTO :COUNTER ) ELSE (
ECHO To edit/change USERNAME and PASSWORD... Please type: OPTION
ECHO.
SET /P user="Please enter the username of your Router:"
IF /I %user%==OPTION ( Goto :EDITBAT )
CLS
ECHO To edit/change USERNAME and PASSWORD... Please type: OPTION
ECHO.
SET /P pass="Please enter the password of your Router:"
IF /I %pass%==OPTION ( Goto :EDITBAT )
CLS
set /a i = 1
GOTO :CHECKACCOUNT
::)

:EDITBAT
start /WAIT notepad %filetxt%
set router_ip=%acct1%
set user=%acct2%
set pass=%acct3%
GOTO :CHECKACCOUNT

:COUNTER
IF %i%==0 ( GOTO :RESETROUTER ) ELSE (
ECHO WAIT %i% seconds...
sleep 1
set /a i = i - 1
CLS
GOTO :COUNTER
)


:RESETROUTER
CLS
ECHO READY to RESET....
ECHO Preparing....
sleep 2

sleep 2
CLS
ECHO Processing....
sleep 5

sleep 2
CLS
ECHO Success....
sleep 5
set /a i = %timer%
CLS
GOTO :COUNTER

:PAUSEEXIT
PAUSE

:EXIT
ECHO.>>%log%
ECHO ========END OF LOG FILE========>>%log%

Kurt Pfeifle · Accepted Answer · 2010-09-23 13:06:55Z

18

Your error as seen comes from wrong formatting. Don't put it all on 1 line. Instead use this:

if /I "%user%"=="insertusername" (
     GOTO :ACCOUNT 
) ELSE (
     GOTO :CHECKPASSACCT 
)

The deeper, underlying reason is: goto :somewhere command needs to be terminated by a newline.

answered Sep 23, 2010 at 13:06

Kurt Pfeifle

91.4k24 gold badges271 silver badges358 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

kikuchiyo Over a year ago

If prefer @pipitas anser over @bta as it is simpler and does not side-step the question of else behavior. Both answers are good though. Just a side note, but I've noticed odd behavior calling goto within a loop where it branches to a line directly above an if statement. In those cases, oddly, placing an echo nul>nul or something similar between the destination and the if statement works like a charm.

jeb Over a year ago

A bit late, but the description is wrong. The syntax is correct, it's absolutly valid to use if "1"=="1" (goto :label1) ELSE (goto :label2). goto doesn't need a newline

bta · Accepted Answer · 2010-09-20 19:30:45Z

11

You can simplify this down to:

:CHECKACCOUNT
if /I "%user%"=="insertusername" GOTO ACCOUNT
GOTO CHECKPASSACCT

:CHECKPASSACCT
if /I "%pass%"=="insertpassword" GOTO ACCOUNT
GOTO COUNTER

The ELSE statements aren't needed. Since the IF block will jump somewhere else, placing the second GOTO on the next line or in an ELSE block should be equivalent.

Also, you need the leading colon when defining a GOTO target but not when referring to the target name inside the GOTO statement itself.

answered Sep 20, 2010 at 19:30

bta

45.4k7 gold badges73 silver badges101 bronze badges

5 Comments

bta Over a year ago

Actually, if there's no code in between the two blocks then you can simplify it further and remove the GOTO CHECKPASSACCT line and the :CHECKPASSACCT line.

bta Over a year ago

When you say it still doesn't work, what error is it giving you and what line does the error occur on? It can't be the same error, since the offending ( no longer exists.

bta Over a year ago

Also, within your :COUNTER block, you probably want to put %i% in double-quotes since you can enter that block before i is ever set.

bta Over a year ago

Adding quotation marks will resolve the syntax error in that line, but your logic is still broken. The variable i needs to be initialized to some valid starting value so that you will never hit the :COUNTER block before you explicitly set it. Editing the batch file and re-testing in the same shell window can cause variables like i to be re-used between runs, so try adding commands like set i= at the top of the batch file to clear out any old data before the script executes (this can hide uninitialized variable problems like this one).

user453089 Over a year ago

aws... its working now.. look like i missing "set i=" Thanks bta for helping me... :)

jeb · Accepted Answer · 2016-04-26 20:46:25Z

3

The problem has nothing to do with the shown code!

The problem is at

:COUNTER
IF %i%==0 ( GOTO :RESETROUTER ) ELSE (

As the variable i isn't defined, the line will be expanded to

IF ==0 ( GOTO :RESETROUTER ) ELSE (

That is an invalid expression.

To find such simple syntax fails, you should enable debugging with ECHO ON.

answered Apr 26, 2016 at 20:46

jeb

83.3k20 gold badges181 silver badges237 bronze badges

Collectives™ on Stack Overflow

IF ELSE problem COMMAND BATCH

3 Answers 3

2 Comments

5 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

2 Comments

5 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related