How can I extract a file path from a Perl string?

Question

I want to find the file name with fullpath from this string

"[exec] /snschome/sns/ccyp/mb_ccsns/bb/cbil5/v85_8/amdocs/iamcust/bil/cl/business/handlers/ClReportsHandler.java:233: cannot resolve symbol"

I want to extract

/snschome/sns/ccyp/mb_ccsns/bb/cbil5/v85_8/amdocs/iamcust/bil/cl/business/handlers/ClReportsHandler.java

and I am trying this in Perl

    $_=$string_from_to_match
    my @extract_file=split(/.*(\/.*)\:.*/);
    print $extract_file[1],"\n";`

but I am getting this output:

/ClReportsHandler.java:233:

It is matching the last / and the last :. How can I change it to first / and first :?

Please edit the formatted version instead of rolling back to the unformatted one. Otherwise your question is unreadable. — Tim Pietzcker
– Tim Pietzcker, Commented Sep 21, 2010 at 14:29

Greg Bacon · Accepted Answer · 2010-09-21 14:24:44Z

4

This is a case where “tacking and stretching” is useful. You know that [exec] followed by whitespace is on the left and colon followed by a line number is on the right. You want what's in between:

#! /usr/bin/perl

use warnings;
use strict;

$_ = "[exec] /snschome/sns/ccyp/mb_ccsns/bb/cbil5/v85_8/amdocs/iamcust/bil/cl/business/handlers/ClReportsHandler.java:233: cannot resolve symbol";

if (/\[exec\]\s*(.+?):\d+/) {
  print $1, "\n";
}

answered Sep 21, 2010 at 14:24

Greg Bacon

141k34 gold badges196 silver badges253 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Black Diamond Over a year ago

hi it worked & from your regular expression i changed mine like this & it is working fine .. my <pre>@extract_file=split(/.*?(\/.*?)\:.*/); </pre>

Ivan Nevostruev · Accepted Answer · 2010-09-21 14:29:26Z

1

If your file name doesn't contain spaces then you can create simple regexp to match all parts:

my ($file, $line, $msg) = ( $string_from_to_match =~ m{(\S+):([^:]+):([^:]+)} );

I've used:

\S+ to match 1 or more non-space symbols
[^:]+ to match 1 or more not : symbols

If you want spaces in path, then the best way is to remove starting [exec] part and split by ::

$string_from_to_match =~ s{^\[exec\]\s+}{};
my ($file, $line, $msg) = split(/:/, $string_from_to_match, 3);

edited Sep 21, 2010 at 14:29

answered Sep 21, 2010 at 14:24

Ivan Nevostruev

28.9k8 gold badges69 silver badges82 bronze badges

Comments

Toto · Accepted Answer · 2010-09-21 14:49:53Z

1

You could try :

#!/usr/bin/perl
use strict;
use warnings;
use 5.10.1;

my $str = "[exec] /snschome/sns/ccyp/mb_ccsns/bb/cbil5/v85_8/amdocs/iamcust/bil/cl/business/handlers/ClReportsHandler.java:233: cannot resolve symbol";
$str =~ s!^[^/]*(/[^:]*):.*$!$1!;
say $str;

Ouput: /snschome/sns/ccyp/mb_ccsns/bb/cbil5/v85_8/amdocs/iamcust/bil/cl/business/handlers/ClReportsHandler.java

answered Sep 21, 2010 at 14:49

Toto

91.7k63 gold badges97 silver badges135 bronze badges

Comments

Tim Pietzcker · Accepted Answer · 2010-09-21 20:56:06Z

-1

Why are you using split() if you want to match?

if ($subject =~ m!(/[^:]+):!) {
    $result = $1;
} else {
    $result = "";
}

should do it.

Explanation:

!: alternative regex delimiter (since I need the / inside)

(: start capturing group

/: match a /. This will always be the first / of the string.

[^:]+: match 1 or more characters except :

): end capturing group

:: match a :

!: regex delimiter

edited Sep 21, 2010 at 20:56

answered Sep 21, 2010 at 14:23

Tim Pietzcker

337k59 gold badges520 silver badges572 bronze badges

Comments

rich · Accepted Answer · 2021-06-29 20:30:42Z

-1

This is what I do:

if ($fullpath =~ /^(.+)\/([^\/]+)/)
{
    my ($path, $file) = ($1, $2);
}

This works by matching anything except the last /. This may not work under Windows of course.

answered Jun 29, 2021 at 20:30

rich

1

Collectives™ on Stack Overflow

How can I extract a file path from a Perl string?

5 Answers 5

1 Comment

Comments

Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

5 Answers 5

1 Comment

Comments

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related