Perl process and store unique values in array

Since your data is nicely structured into one line per data item, and since Perlby default processes input line by line, I suggest doing that instead of messing with $/ or regexps to split the input records. This does require you to remember the JIRA issue ID from the first line of each record, but that's simple — just store it in a variable declared outside the loop, like this:

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper qw(Dumper);

my %records;
my $jiraID;
while (<>) {
    chomp;
    if (/^JIRA: (.*)/ and not defined $jiraID) {
        $jiraID = $1;
        $records{$jiraID} = {};  # wipe out any old data for this ID
    } elsif (/^(Program|Reviewer|Description|rev):(.*)/ and defined $jiraID) {
        $records{$jiraID}{$1} = $2;
    } elsif (/^-{20,}$/) {
        undef $jiraID;  # end of record
    } else {
        die qq(Unexpected input line "$_");
    }
}

print Dumper(\%records);

The code above reads its input from any file(s) provided as command line arguments, or from standard input if there aren't any, using the <> default input operator. If you want to read from a specific file handle that you've opened yourself, you can of course provide one.

Note that the code above stores only the last record for each ID. If you want to store all of them in an array, replace the line:

        $records{$jiraID} = {};  # wipe out any old data for this ID

with:

        push @{$records{$jiraID}}, {};  # start new record for this ID

and change the line:

        $records{$jiraID}{$1} = $2;

to:

        $records{$jiraID}[-1]{$1} = $2;

Ps. The regexps in the code above are based on your sample data. If your real data has other types of lines in it (or variations e.g. in the amount of whitespace), you'll need to adjust them to match those lines too. I coded the script to die if it sees anything unexpected, so it's easy to tell if that happens.

Update: Based on the sample output you posted while I was writing this answer, it looks like you want to group the data by both the JIRA and the Program lines. That's easy enough to do as well, e.g. like this:

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper qw(Dumper);

my %records;
my $jiraID, $progID;
while (<>) {
    chomp;
    if (/^JIRA:\s*(.*)/ and not defined $jiraID) {
        $jiraID = $1;
    } elsif (/^Program:\s*(.*)/ and defined $jiraID and not defined $progID) {
        $progID = $1;
        push @{$records{$jiraID}{$progID}}, {};  # start new record for these IDs
    } elsif (/^(Reviewer|Description|rev):(.*)/ and defined $progID) {
        $records{$jiraID}{$progID}[-1]{$1} = $2;
    } elsif (/^-{20,}$/) {
        undef $jiraID, $progID;  # end of record
    } else {
        die qq(Unexpected input line "$_");
    }
}

print Dumper(\%records);

Note that I grouped the output data structure first by the JIRA ID and then by the program, but of course those would be easy to swap (or even combine into a single hash key, if you prefer).

This doesn't handle the final output, but this may be a simplified approach to storing lists of lists for each hash element (ticket id), along with some sample output at the end. It's not formatted the way you want, but that should be easy enough:

use strict;

my (%jira, @values, $ticket_id);

open my $IN, '<', 'jira.txt' or die;
while (<$IN>) {
  chomp;
  my ($key, $val) = split /:\s*/;

  if ($key eq 'JIRA') {
    if (@values) {
      push @{$jira{$ticket_id}}, [ @values ];
      @values = ();
    }
    $ticket_id = $val;

  } elsif ($key eq 'Program') {
    $values[0] = $val;
  } elsif ($key eq 'Reviewer') {
    $values[1] = $val;
  } elsif ($key eq 'Description') {
    $values[2] = $val;
  } elsif ($key eq 'rev') {
    $values[3] = $val;
  }
}
close $IN;

push @{$jira{$ticket_id}}, [ @values ];

while (my ($ticket, $ref) = each %jira) {
  print "$ticket =>\n";
  foreach my $line_ref (@$ref) {
    print join "\t", @$line_ref, "\n";
  }
}

Sample output:

COM-1234 =>
Development     John Wick       Genral fix      r345676
Development     None    Updating Received       r909276
COM-6789 =>
Testing Balise Mat      Audited r876391
Testing Chan Joe        SO hwat         r698392
Testing Chan Joe        Paid the Due    r327896