How to create a cmake header-only library that depends on external header files?

Question

I have a project with the following file structure:

project
 |
 |-------> lib1
 |           |----> lib1.h
 |
 |-------> lib2
 |           |----> lib2.h
 |
 |-------> main.cc

The two libs lib1 and lib2 only contain header files while lib2.h includes lib1.h, and main.cc includes lib2.h.

How do I write the cmake file for this project now? I tried to create an interface library for lib2, but the compiler can't find lib1.h. Here are the contents of my cmake files:

CMakeLists.txt for lib2:

add_library(lib2 INTERFACE)
target_sources(lib2 INTERFACE lib2.h)
target_include_directories(lib2 INTERFACE ../lib1/lib1.h)

CMakeLists.txt for the whole project:

add_executable(project main.cc)
target_link_libraries(project lib2)

What's the problem in the cmake files?

Can't you just list your headers in add_executable and remove all add_library? — arrowd
– arrowd, Commented Oct 6, 2016 at 6:38
One thing that seems odd in your source code and could explain the problem: target_include_directories() is only for directories that contain header files. So it should be target_include_directories(lib2 INTERFACE ../lib1). — Florian
– Florian, Commented Oct 6, 2016 at 6:59

starball · Accepted Answer · 2022-09-17 23:12:40Z

29

As stated in the comments, target_include_directories should be given a path to a directory, not to a file.

Moreover, if you want to create a dependency for lib2 on lib1, you should do it through target_link_libraries: a dependency is not only about include directories, but also about compile options, definitions, target properties...

target_sources doesn't work with interface libraries. From this answer, You can use a custom target without commands to associate the sources to a target without impacting the build process (for msvc, QtCreator and other GUI-based tools, this makes the sources accessible through the IDE; AFAIK it's useless for other build tools).

Your cmake may look like this:

add_library(lib1 INTERFACE)
target_sources(lib1 INTERFACE lib1.h)

target_include_directories(lib1 INTERFACE
    "${PROJECT_SOURCE_DIR}/lib1"
)

add_library(lib2 INTERFACE)
if(MSVC)
    add_custom_target(lib2.headers SOURCES lib2.h)
endif()

target_include_directories(lib2 INTERFACE
    "${PROJECT_SOURCE_DIR}/lib2"
)

target_link_libraries(lib2 INTERFACE lib1)

add_executable(project main.cc)
target_link_libraries(project lib2)

Advanced tip: you can specify a different directory in target_include_directories for the build tree and the install tree (see documentation):

target_include_directories(lib1 INTERFACE
    $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/lib1>
    $<INSTALL_INTERFACE:${YOUR_INSTALL_DIR}/lib1>
)

edited Sep 17, 2022 at 23:12

starball♦

59.6k53 gold badges316 silver badges1k bronze badges

answered Oct 6, 2016 at 7:25

rocambille

16.2k12 gold badges54 silver badges71 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

helmesjo Over a year ago

target_sources shouldn't be needed since target is of type "INTERFACE", and isn't compiled by itself. Passing sources directly to add_library even gives the following error: add_library INTERFACE library requires no source arguments.

Tomilov Anatoliy Over a year ago

BTW target_sources is also needed for sources to be visible in Projects pane of QtCreator IDE easily.

Mohammed Safwat Over a year ago

I'm using cmake 3.5.1 and for the line target_link_libraries(lib2 lib1) I get this error INTERFACE library can only be used with the INTERFACE keyword of target_link_libraries I guess it means lib2 by the interface library here. I can get past this error if I add the INTERFACE keyword in the target_link_libraries command before lib1. target_link_libraries(lib2 INTERFACE lib1)

Michał Kawiecki · Accepted Answer · 2017-03-01 14:56:09Z

5

I've used an empty _only_for_compiling_the_lib.cpp file as the simplest and fastest workaround, but clearly the above solution is strongly advised.

I simply wasn't aware of INTERFACE keyword.

answered Mar 1, 2017 at 14:56

Michał Kawiecki

3853 silver badges7 bronze badges

1 Comment

IC_ Over a year ago

I still can't understand how do other solutions work and would prefer empty cpp again

Pankaj Misra · Accepted Answer · 2019-03-23 21:02:56Z

3

This problem was due to full path issue of INTERFACE library files, which got fixed in cmake version 3.13.

For more info: https://gitlab.kitware.com/cmake/cmake/issues/17556

This page also contains an example for better understanding.

answered Mar 23, 2019 at 21:02

Pankaj Misra

1931 gold badge1 silver badge13 bronze badges

Collectives™ on Stack Overflow

How to create a cmake header-only library that depends on external header files?

3 Answers 3

3 Comments

1 Comment

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

3 Comments

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related