Find max node value

Question

I have a xml given below:

<root title="الصفحة الرئيسة">
   <item title="الصفحة الرئيسة" itemuri="tcm:8-29-4" ShowInNav="True" type="sg" pageuri="tcm:8-10592-64" sLink="/ara/index.aspx">
      <item title="من نحن" itemuri="tcm:8-779-4" ShowInNav="True" type="sg" pageuri="tcm:8-9934-64" navorder="00500" sLink="/ara/about/index.aspx">
      </item>
      <item title="برامجنا" itemuri="tcm:8-817-4" ShowInNav="True" type="sg" pageuri="tcm:8-10112-64" navorder="00100" sLink="/ara/courses/language-study-abroad.aspx">
      </item>
      <item title="مدارسنا" itemuri="tcm:8-824-4" ShowInNav="True" type="sg" pageuri="tcm:8-10162-64" navorder="00300" sLink="/ara/schools/english-language.aspx"> 
      </item> 
   </item>
</root>

Now I want to the value of maximum navorder, so that I can use that value further in "if" condition.

Dimitre Novatchev · Accepted Answer · 2009-01-06 15:00:33Z

Below is the XSLT 1.0 code of two possible solutions.

A third solution is to use EXSLT.

A fourth solution is to use the maximum template of FXSL.

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

    <xsl:template match="/">
      <xsl:variable name="vMax1" select=
       "*/*/*/@navorder[not(. &lt; ../../*/@navorder)][3]"/>

       $vMax1: <xsl:value-of select="$vMax1"/>

      <xsl:variable name="vMax2">
        <xsl:call-template name="max">
          <xsl:with-param name="pSeq" 
               select="*/*/*/@navorder"/>
        </xsl:call-template>
      </xsl:variable>

       $vMax2: <xsl:value-of select="$vMax2"/>

    </xsl:template>

    <xsl:template name="max">
      <xsl:param name="pSeq"/>

      <xsl:variable name="vLen" select="count($pSeq)"/>

      <xsl:if test="$vLen > 0">
        <xsl:choose>
          <xsl:when test="$vLen = 1">
            <xsl:value-of select="$pSeq[1]"/>
          </xsl:when>
          <xsl:otherwise>
            <xsl:variable name="vHalf" 
             select="floor($vLen div 2)"/>

            <xsl:variable name="vMax1">
              <xsl:call-template name="max">
                <xsl:with-param name="pSeq" 
                 select="$pSeq[not(position() > $vHalf)]"/>
              </xsl:call-template>
            </xsl:variable>

            <xsl:variable name="vMax2">
              <xsl:call-template name="max">
                <xsl:with-param name="pSeq" 
                 select="$pSeq[position() > $vHalf]"/>
              </xsl:call-template>
            </xsl:variable>

            <xsl:choose>
              <xsl:when test="$vMax1 >= $vMax2">
                <xsl:value-of select="$vMax1"/>
              </xsl:when>
              <xsl:otherwise>
                <xsl:value-of select="$vMax2"/>
              </xsl:otherwise>
            </xsl:choose>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:if>
    </xsl:template>
</xsl:stylesheet>

When the above transformatio is applied on the original XML document:

<root title="الصفحة الرئيسة">
    <item title="الصفحة الرئيسة" itemuri="tcm:8-29-4"
          ShowInNav="True" type="sg"
          pageuri="tcm:8-10592-64"
          sLink="/ara/index.aspx">
        <item title="من نحن" itemuri="tcm:8-779-4"
              ShowInNav="True" type="sg"
              pageuri="tcm:8-9934-64"
              navorder="00500"
              sLink="/ara/about/index.aspx"/>
        <item title="برامجنا" itemuri="tcm:8-817-4"
              ShowInNav="True" type="sg"
              pageuri="tcm:8-10112-64"
              navorder="00100"
              sLink="/ara/courses/language-study-abroad.aspx"/>
        <item title="مدارسنا" itemuri="tcm:8-824-4"
              ShowInNav="True" type="sg"
              pageuri="tcm:8-10162-64"
              navorder="00300"
              sLink="/ara/schools/english-language.aspx"/>
  </item>
</root>

the wanted result is produced:

   $vMax1: 00500

   $vMax2: 00500

Dirk Vollmar · Accepted Answer · 2009-01-06 10:15:05Z

2

the following is a solution using XPath 1.0:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="/">
      <xsl:variable name="maximum">
        <xsl:value-of select="/root/item//item[not(preceding-sibling::item/@navorder > @navorder or following-sibling::item/@navorder > @navorder)]/@navorder"/>
      </xsl:variable>
      <max>
        <xsl:value-of select="$maximum"/>
      </max>
    </xsl:template>
</xsl:stylesheet>

The expression

/root/item//item[not(preceding-sibling::item/@navorder > @navorder or following-sibling::item/@navorder > @navorder)]/@navorder

filters all item nodes so that there is no preceding or following node that has a higher navorder value on the same level.

answered Jan 6, 2009 at 10:15

Dirk Vollmar

177k53 gold badges261 silver badges318 bronze badges

2 Comments

annakata Over a year ago

ha - the preceding/following sibling trick, yeah this is a good fast answer and should probably be accepted. The math:max template is possible a better general solution though.

Dirk Vollmar Over a year ago

However - as ususal with XPath/XSLT - such an expression will not be that efficient on large nodesets :-(

Hank Gay · Accepted Answer · 2009-01-06 09:43:55Z

1

I found this forum post as one potential solution.

Of course, if you have access to XPath 2.0, there's a more direct solution: fn:max(arg, arg, …)

answered Jan 6, 2009 at 9:43

Hank Gay

72.4k36 gold badges164 silver badges224 bronze badges

1 Comment

Manoj Singh Over a year ago

I am using xslt 1.0, please give examples using xslt 1.0

annakata · Accepted Answer · 2009-01-06 09:44:21Z

0

Couple of ways: with xpath 2 you can use the max() function, but if you're in xslt 1 you'll have to use sort in a for-each and then put the item at position 1 in your variable.

answered Jan 6, 2009 at 9:44

annakata

76k18 gold badges116 silver badges181 bronze badges

2 Comments

Manoj Singh Over a year ago

can you please give one example with the given xml

annakata Over a year ago

my example would just be a template along the lines of OJ's solution

OJ. · Accepted Answer · 2009-01-07 11:31:02Z

0

Have a look at this. Then use it in your xpath

/root/item[@navorder = math:max(/root/item/@navorder)]

Or something similar :)

NOTE This requires the use of EXSLT.

NOTE 2: No it doesn't. Just copy and paste the code.

edited Jan 7, 2009 at 11:31

answered Jan 6, 2009 at 9:43

OJ.

29.6k6 gold badges59 silver badges71 bronze badges

3 Comments

Manoj Singh Over a year ago

its giving error given below: Error =System.Xml.Xsl.XsltException: Prefix 'math' is not defined. at System.Xml.Xsl.InputScopeManager.ResolveNonEmptyPrefix(String prefix) Please help

annakata Over a year ago

you'll have to add the math namespace

Dirk Vollmar Over a year ago

and you'll have to get / install the exslt extensions

Collectives™ on Stack Overflow

Find max node value

5 Answers 5

Comments

2 Comments

1 Comment

2 Comments

3 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

5 Answers 5

Comments

2 Comments

1 Comment

2 Comments

3 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related