Wrong result when using a global variable in Fortran

Question

I'm learning the basics of Fortran. I created a simple subroutine initializing a matrix:

program test
   integer, parameter :: n = 1024
   real :: a(n, n)
   call init(a)
   write (*, *) a(1, 1)
end program

subroutine init(a)
   real :: a(n, n)
   a(:, :) = 3.0
end subroutine

Then the output is 0.0 instead of expected 3.0. Apart from that, valgrind says that:

==7006== Conditional jump or move depends on uninitialised value(s)
==7006==    at 0x400754: init_ (in /home/marcin/proj/mimuw/fortran/test)
==7006==    by 0x4007A4: MAIN__ (in /home/marcin/proj/mimuw/fortran/test)
==7006==    by 0x40083B: main (in /home/marcin/proj/mimuw/fortran/test)

Why? The n parameter is correctly recognized by the compiler and should be a global one.

I compiled the program with gfortran 6.3.1

n isn't a global object. If you add implicit none in the subroutine you will see an error. — francescalus
– francescalus, Commented Feb 3, 2017 at 13:11
Oh, so I need implicit none in the subroutines too! Did not know about it. When testing I tried using that in program but not in the subroutine. Is it possible to use implicit none globally? — marmistrz
– marmistrz, Commented Feb 3, 2017 at 13:40
Because of the independent compilation nature of various program units (as touched on by Vladimir F), there's no such thing really as "globally" for scoping. You can find detail about implicit typing rules in this question. — francescalus
– francescalus, Commented Feb 3, 2017 at 14:25

Graham · Accepted Answer · 2017-09-28 00:27:08Z

6

n is not a global variable, it is a local variable of the main program.

The subroutine is a completely independent compilation unit from the main program and they do not share any information.

A subroutine can "see" other variables of the parent module, if it is a module procedure, or variables of a parent (host) procedure or program if it is an internal procedure.

Be sure to read about the structure of Fortran programs and use modules as much as possible. Prefer modules over internal procedures. You will see how to put the subroutine into a module or how to make it internal to the main program in the link.

I did not mention common blocks, just don't use them, they are obsolete. And rember to use implicit none in every compilation unit.

edited Sep 28, 2017 at 0:27

Graham

7,86020 gold badges67 silver badges92 bronze badges

answered Feb 3, 2017 at 13:25

Vladimir F Героям слава

60.7k4 gold badges82 silver badges131 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

marmistrz Over a year ago

So n was just implicitly declared when I used it in the subroutine?

Chaosit Over a year ago

@marmistrz yes, with implicit typing everything that starts with i,n and some other letters(don't even remember which ones) are declared as integers. Generally you should not use implicit typing since this may lead to undesired behavior sometimes. I can suggest reading Modern Fortran Explained by Michael Metcalf - this can help you with onboarding process.

Holmz · Accepted Answer · 2017-02-04 05:58:22Z

Assuming that you want it everywhere, then one uses a COMMON block in the f77 era, and a MODULE now.

I CAPITALISED most of the changes. And if there is no error gives a few ways to consider understanding N in the SUBROUTINE, and an ELEMENTAL FUNCTION would likely be worthwhile to try here too.

MODULE MyMODULE
  integer, parameter :: n = 1024
END MODULE MyMODULE

!%%%%%%%%%% 
program test
USE MyModule
IMPLICIT NONE
! done up in ˆmoduleˆ...!  integer, parameter :: n = 1024
REAL, DIMENSION(n,n) :: A

CALL Alternative_Init(A, 3.3)
WRITE (*,*) a(1, 1)

CALL Alternative2_Init(A, n, 1.23)
WRITE (*,*) a(1, 1)

call init(a)
write (*, *) a(1, 1)
END PROGRAM TEST

!%%%%%%%%%% 
subroutine init(a)
USE MyModule
IMPLICIT NONE

real :: a(n, n)
a(:, :) = 3.0

RETURN
END SUBROUTINE init


!%%%%%%%%%% 
SUBROUTINE Alternative_Init(a, Val4A)
USE MyModule
IMPLICIT NONE

REAL, DIMENSION(:,:) , INTENT(INOUT) :: a
REAL                 , INTENT(IN  )  :: Val4A

a(:, :) = Val4A
! or just... A = Val4A ! which does them all too.

RETURN
END SUBROUTINE Alternative_Init

!%%%%%%%%%% 
SUBROUTINE Alternative2_Init(a, n, Val4A)
!!!!  USE MyModule
IMPLICIT NONE

INTEGER              , INTENT(IN   ) :: n
REAL, DIMENSION(n,n) , INTENT(  OUT) :: a
REAL                 , INTENT(IN   ) :: Val4A

A = Val4A

RETURN
END SUBROUTINE Alternative2_Init

Collectives™ on Stack Overflow

Wrong result when using a global variable in Fortran

2 Answers 2

2 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related