How to match strings from an XML file using batch and assign to variable?

Question

I have an XML file (generated by a third party tool) which is of format

<?xml version="1.0" encoding="UTF-8"?><ROOT test_count="22" test_fail_count="1" test_pass_count="21".......</ROOT>

All the content is in one line of the file with name Report.xml.

I have been trying to write a batch script

@echo off
setlocal EnableDelayedExpansion
set "Report="
for /f "delims=" %%x in (Report.xml) do set "Report=!Report! %%x"
REm set /p Report=< %Results_File%
echo report is !Report!
call:parseVal !Report!
exit/b

:parseVal
setlocal enableDelayedExpansion
set val="%~1"
echo %val%
echo !val!|findstr /rc:"test_count=.[0-9]*." >nul || (
    echo !val!
    EndLocal
    exit /b
)

rem ..

Basically I am trying to grab values for test_count(22), test_fail_count(1) and test_pass_count(21) from the XML file.

Any ideas on how to achieve this?

unfortunately , that is a requirement in my case, i.e it cannot be *.sh , however if there a good option in Perl or other scripting language I might be able to consider it. — TechArch
– TechArch, Commented Feb 5, 2017 at 21:32
Can't it be JavaScript? From what I remember Windows used to have this "scripting host" thing. Isn't that still there? — melpomene
– melpomene, Commented Feb 5, 2017 at 21:37
Yep, looks like WSH is available from Win98 onwards (Win10 still has it): en.wikipedia.org/wiki/Windows_Script_Host — melpomene
– melpomene, Commented Feb 5, 2017 at 21:49

Magoo · Accepted Answer · 2017-02-05 21:35:59Z

1

@ECHO Off
SETLOCAL
SET "sourcedir=U:\sourcedir"
SET "filename1=%sourcedir%\q42057260.txt"
SET "testcount="
SET "testfailcount="
FOR /f "usebackqdelims=" %%a IN ("%filename1%") DO (
 SET "xmlline=%%a"
 CALL :process
)

ECHO test count=%testcount% test fail count=%testfailcount%

GOTO :EOF

:process
:: dispose of awkward characters
SET "xmlline=%xmlline:?= %"
SET "xmlline=%xmlline:>= %"
SET "xmlline=%xmlline:<= %"
CALL :select %xmlline%
GOTO :EOF

:select
IF /i "%~1"=="" GOTO :EOF
IF DEFINED testcount IF DEFINED testfailcount GOTO :EOF
IF /i "%~1"=="test_count" SET /a testcount=%~2
IF /i "%~1"=="test_fail_count" SET /a testfailcount=%~2
SHIFT
GOTO select

GOTO :EOF

You would need to change the setting of sourcedir to suit your circumstances.

I used a file named q42057260.txt containing your data for my testing.

Read the file to %%a and transfer to xmlline.

Use :process to remove awkward characters (those with a special meaning to cmd) by replacing each with a space, then pass the resultant line to :select as a parameter-list.

look at each parameter in turn, stripping quotes. When the target strings appear, set their storage variables to the following value. When both values are assigned, bail out.

and report results.

answered Feb 5, 2017 at 21:35

Magoo

80.8k8 gold badges68 silver badges92 bronze badges

Sign up to request clarification or add additional context in comments.

6 Comments

TechArch Over a year ago

for some reason the code does'nt move past the "for loop". it exits out and prints test count= test fail count=

Magoo Over a year ago

Batch syntax is very specific. It's best to cut-and-paste. If you were to add a line echo "%%~1 on a new line directly under :select, then you should see the routine examining each element provided in turn.

TechArch Over a year ago

that worked. it was a typo on my part thanks a lot !

TechArch Over a year ago

For some reason , the code isnt working again. I copy pasted into notepad++ coult that be the problem?

Magoo Over a year ago

@mofi: The options parameter merely states that the string contains one or more keywords - although the examples use a space-separator. cmd appears to see whether the option is contained in the option string, deletes any option found from the string before checking for the next option. Hence "delims=#usebackq" is valid; usebackq is detected first & eliminated, # is used as delims. I habitually use the delims option last to circumvent typos. Would "delims=#usebackq" & "delims=# usebackq" act differently? I treat the space as optional & agree it's clearer but more typing.

|

user6811411 · Accepted Answer · 2017-02-05 22:21:08Z

0

Provided the structure and order of Report.xml is constant this could do (cmd line)

for /f "tokens=5,6 delims=<> " %A in (Report.xml) Do @Set %A&Set %B

Sample output with your Report.xml

> set test
test_count="22"
test_fail_count="1"

answered Feb 5, 2017 at 22:21

user6811411

Collectives™ on Stack Overflow

How to match strings from an XML file using batch and assign to variable?

2 Answers 2

6 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

6 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related