Sorting a multidimensional array in awk

Question

I am trying to sort a multidimensional array in ascending order. What am i doing wrong?

  for (i=0; i in avg; i++)
        for (j=0; j<=i; j++)
           if (avg[j]>avg[j+1])
           {
                temp=a[j];
                avg[j]=a[j+1];
                avg[j+1]=temp;         
           }

Sample input 1.43 2.14 1.57

Exped output 1.43 1.57 2.14

it didn't work i have the feeling that i am not referencing elements the propper way — Radoslav Todorov
– Radoslav Todorov, Commented Feb 24, 2017 at 21:56

Ed Morton · Accepted Answer · 2017-02-25 00:53:12Z

3

Your array is not multidimensional. In any case, to sort an array using GNU awk for "sorted_in":

$ awk 'BEGIN{
    split("1.43 2.14 1.57",a)

    print "ascending:"
    PROCINFO["sorted_in"]="@val_num_asc"
    for (i in a) print a[i]

    print "\ndescending:"
    PROCINFO["sorted_in"]="@val_num_desc"
    for (i in a) print a[i]
}'
ascending:
1.43
1.57
2.14

descending:
2.14
1.57
1.43

edited Feb 25, 2017 at 0:53

answered Feb 25, 2017 at 0:47

Ed Morton

209k18 gold badges90 silver badges212 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Akshay Hegde Over a year ago

^1 nice presentation of sorted_in.

Jose Ricardo Bustos M. · Accepted Answer · 2017-02-24 22:14:42Z

1

You are using bubble sorting, you have several errors .... I show an example working

awk '
    BEGIN{
    n = split("1.43 2.14 1.57", avg, " ")
    for (i=1; i<=n-1; ++i)
        for (j=i+1; j<=n; ++j)
            if (avg[i]>avg[j]){
                temp=avg[j]
                avg[j]=avg[i]
                avg[i]=temp        
            }
    for (i=1; i<=n; ++i) printf "%s%s",avg[i],(i==n?ORS:OFS)
}'

you get,

1.43 1.57 2.14

edited Feb 24, 2017 at 22:14

answered Feb 24, 2017 at 22:06

Jose Ricardo Bustos M.

8,1847 gold badges44 silver badges66 bronze badges

Comments

Bertrand Martel · Accepted Answer · 2017-02-25 01:20:53Z

1

Also, if you have access to gawk extensions you can use asort() :

awk 'BEGIN{
        a[1]=1.43;
        a[2]=2.14;
        a[3]=1.57; 

        n = asort(a); 

        for(j = 1; j <= n; j++) { 
            print a[j] 
        }
     }'

edited Feb 25, 2017 at 1:20

answered Feb 24, 2017 at 22:14

Bertrand Martel

46.1k17 gold badges156 silver badges170 bronze badges

Collectives™ on Stack Overflow

Sorting a multidimensional array in awk

3 Answers 3

1 Comment

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

1 Comment

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related