I would like to replace the word "hello" with "world" on slide 1 of the ppt. How can I do that using VBA script.
-
1I suggest you read something like Getting Started with VBA in PowerPoint 2010, then try writing a bit of code yourself. If you get stuck, show us what you've done so we can help.Jean-François Corbett– Jean-François Corbett2017-03-02 12:51:26 +00:00Commented Mar 2, 2017 at 12:51
-
Actually, I'm new to VBA and I already did some research before, however I'm not find the proper information that I need. Could you please share example?Rahul Dagli– Rahul Dagli2017-03-02 13:32:39 +00:00Commented Mar 2, 2017 at 13:32
-
Check out this sample: skphub.com/ppt00025.htm#2Shyam Pillai– Shyam Pillai2017-08-10 02:51:36 +00:00Commented Aug 10, 2017 at 2:51
Add a comment
|
2 Answers
Sub findAndReplaceText()
Dim sld As Slide
Set sld = ActivePresentation.Slides(1)
Dim shp As Shape
For Each shp In sld.Shapes
If shp.HasTextFrame Then
If shp.TextFrame.HasText Then
shp.TextFrame.TextRange.Text = Replace(shp.TextFrame.TextRange.Text, "hello", "world")
End If
End If
Next shp
End Sub
Reference: https://www.youtube.com/watch?v=BYfKvVmtAGE
3 Comments
Steve Rindsberg
Note that this will not find/replace text in tables, smartart, grouped shapes, charts etc.
RowanC
Note that this will not maintain any line or section specific formatting, as it replaces all of the text in the shape
Rob
additionally to checking the HasText, you will also want to avoid grouped items as they will fail on TextRange. -> If shp.TextFrame.HasText And shp.Type <> msoGroup Then
In a slight addendum to the previous answer, in office 2016, I used the following method to achieve the same thing, however this method lets me keep formatting within the text range, as it only replaces the specific text searched for:
Sub findAndReplaceText(sld As PowerPoint.Slide, findText As String, replaceText As String)
Dim shp As PowerPoint.Shape
Dim textLoc As PowerPoint.TextRange
For Each shp In sld.Shapes
If shp.HasTextFrame Then
If shp.TextFrame.HasText Then
Set textLoc = shp.TextFrame.TextRange.Find(findText) 'use Find function to get the textrange for the string being searched for
If Not (textLoc Is Nothing) Then 'if something is found
textLoc.Text = replaceText 'then replace it
End If
End If
End If
Next shp
End Sub
Comments
