How do I reference a class instance from another class instance in Actionscript 3.0?

Question

Quick question. I have been Googling this all morning, but it's either not there, or else written in a way that doesn't register. I am inclined to believe the latter, as this seems like it should be something completely trivial to me.

I made a small Flash file using AS 3.0, and this is the first time I've really been able to stick to the OOP way of doing things and not hack together a mix of stuff from the timeline to get around not having everything work in the classes.

So I'd like to keep it that way, but one thing is eluding me: I can't call a method of an instance of another class (than the one I'm calling from) without resorting to "DocumentClass(root).instanceName.method."

Intuition tells me there has to be a better way of doing this (like, without having to reference the document class every time I call another class instance's function; and CERTAINLY without having to use the word "root" - that just seems so Flash 5 to me.

Does anybody have a better way of doing this that they can share?

Thanks in advance! SS

edit: Here's some relevant code: Main class:

package myApp {

    import flash.display.*;
    import flash.events.*;

    public class Main extends flash.display.MovieClip {

        public var background;

        public var control;

        public function Main() {

            //load the background
            this.background = new Background();
            this.addChild(background);

            //load the control
            this.control = new Control;
            this.addChild(control);
        }
    }
}

Background class:

package myApp {

    import flash.display.*;
    import flash.events.*;

    public class Background extends flash.display.MovieClip {

        public function Background() {
            this.x = 0;
            this.y = 0;
        }

        public function doSomething() {
            //do something here
        }

    }
}

Control class:

package myApp {

    import flash.display.*;
    import flash.events.*;

    public class Control extends flash.display.MovieClip {

        private var section01;
        private var section02;
        private var section03;

        public function Control() {

            //some constructor code here

        }

        public function doSomethingCaller() {
            MyApp(root).background.doSomething();   <--- HERE
        }
    }
}

TM_ · Accepted Answer · 2010-12-10 07:33:06Z

1

You can try the following approach:

package
{
    import com.A;
    import com.B;
    import flash.display.MovieClip;

    public class Main extends MovieClip
    {
        private var _a:A;
        private var _b:B;

        public function get a():A
        {
            return _a;

        }// end function

        public function Main():void
        {
            init();

        }// end function

        private function init():void
        {
            _a = new A();
            _b = new B(this);

        }// end function

    }// end class

}// end package

In your document class "Main", classes "A" and "B" are imported. The private properties "_a" and "_b" are declared in the "Main" class for the "A" and "B" class. Next there is a getter method called "a" that returns "_a". Next there is a private method called "init()" that you call from the "Main" class's constructor. In the method "init()", the "_a" and "_b" properties are instantiated, however for "_b", a reference to "Main" is parsed using the "this" keyword.

package com
{
    import flash.display.MovieClip;

    public class A extends MovieClip
    {
        public function A():void {}// end function

        public function traceClassName():void
        {
            trace("Class name: A");

        }// end function

    }// end class

}// end package

In the class "A" there is a public method called "traceClassName()" that traces the string "Class name: A" when invoked.

package com
{
    public class B
    {
        private var _main;

        public function B(p_main):void 
        {
            _main = p_main;
            _main.a.traceClassName();

        }// end function

    }// end class

}// end package

In the class "B" you have a private property called "_main". In the "B" class's constructor you have a parameter for the reference of the Main class to be parsed when the "B" class is instantiated. The "_main" property is then assigned the reference to the "Main" class. Now you can access the instance of "A" through the reference of the "Main" class from the "B" class.

There are many approaches, this is just one of the simpler ways, although I think there are better ones. You should present the source code for your flash app/movie, so I and everyone else can get a better idea of which would suit you.

I hope this helped :)

answered Dec 10, 2010 at 7:33

TM_

3,2072 gold badges20 silver badges15 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

StormShadow Over a year ago

I'm sorry, but this just went right over my head. Like, I don't understand why you are importing extra classes into your Main class, and it makes me think maybe I'm doing something wrong. Let me post some code above and maybe you'll see what I'm talking about.

TM_ Over a year ago

Imagine "A" and "B" class are your "Background" and "Control" classes respectively. They are both in a folder called "com" (which in your case is called "MyApp") that I imported into the "Main" class. The "Main" class in my example is in the same folder as the flash document called "Main.fla". If you don't understand what getter and setter methods are or what access modifiers are(e.g. public, private etc) then I can edit my answer to incorparate those explainations if you want.

StormShadow Over a year ago

Wow. I just got it, but J.H. Rollerskating Christ that's a lot of hoops to jump through just to be able to call another instance's method. Guess I'd better just accept it as one of Actionscript's limitations and stick to DocumentClass(root). Thanks anyway!

TM_ Over a year ago

To be honest there are much better approaches, I just went with something that was easy to understand. In your case, instead of parsing a reference of Main to B, you could simply parse reference of A to B. If you want, you can send me your flash app/movie, and I can look over it anytime. Contact details are on my profile. Hope I helped a little :)

Collectives™ on Stack Overflow

How do I reference a class instance from another class instance in Actionscript 3.0?

1 Answer 1

4 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

4 Comments

Your Answer

Sign up or log in

Post as a guest

Related