Converting output in multiple rows to single row with separate column using awk

Question

I have a output like below which I wish to convert it to single row (without space)

 vol sysvol : 25654
 vol sysvol : 39%
 vol sysvol : 820928KB
 vol vol01 : 502
 vol vol01 : 0%
 vol vol01 : 16064KB
 vol vol02 : 65491
 vol vol02 : 99%
 vol vol02 : 2095712KB
 DB : 91647
 DB : 46%
 DB : 2932704KB

I used command below

awk 'NR%3{printf "%s,",$0;next;}1'

but it returns me output like

 vol sysvol : 25654 , vol sysvol : 39% , vol sysvol : 820928KB
 vol vol01 : 502 , vol vol01 : 0% , vol vol01 : 16064KB
 vol vol02 : 65491 , vol vol02 : 99% , vol vol02 : 2095712KB
 DB : 91647 , DB : 46% , DB : 2932704KB

Where as I wish to have output like

vol sysvol: 25654 , 39%  , 820928KB
vol vol01 : 502 , 0% , 16064KB
vol vol02 : 65491 ,  99% ,  2095712KB
DB : 91647 , 46% ,  2932704KB

Please help.

karakfa · Accepted Answer · 2017-05-27 03:25:32Z

2

awk to the rescue!

awk -F: -v OFS=, '{if (NR%3==1) printf "%s : %s",$1,$2 OFS;
                   else printf "%s", $2 (NR%3?OFS:ORS)}' file  

vol sysvol  :  25654, 39%, 820928KB                     
vol vol01  :  502, 0%, 16064KB                                     
vol vol02  :  65491, 99%, 2095712KB                             
DB  :  91647, 46%, 2932704KB

answered May 27, 2017 at 3:25

karakfa

67.8k8 gold badges45 silver badges59 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Ed Morton · Accepted Answer · 2017-05-27 05:21:09Z

0

$ cat tst.awk
BEGIN { FS=":"; OFS="," }
$1 != prev { if (NR>1) print rec; rec=$0; prev=$1; next }
{ rec = rec OFS $2 }
END { print rec }

$ awk -f tst.awk file
 vol sysvol : 25654 , 39% , 820928KB
 vol vol01 : 502 , 0% , 16064KB
 vol vol02 : 65491 , 99% , 2095712KB
 DB : 91647 , 46% , 2932704KB

answered May 27, 2017 at 5:21

Ed Morton

209k18 gold badges90 silver badges212 bronze badges

Collectives™ on Stack Overflow

Converting output in multiple rows to single row with separate column using awk

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related