Web scraping with Excel and VBA

Question

I am trying to extract the team names but i get the "Run time error 424 Object required" on this line

Set lists = html.getElementsByClassName("KambiBC-event-item__participants-container")

, if anyone could point me in the right direction it would be nice.

    Sub useClassnames()
    Dim lists As IHTMLElementCollection
    Dim anchorElements As IHTMLElementCollection
    Dim ulElement As HTMLUListElement
    Dim liElement As HTMLLIElement
    Dim row As Long
    Dim ie As InternetExplorer

       Set ie = New InternetExplorer

           With ie.navigate "https://www.unibet.ro/betting#filter/all/all/all/all/in-play"
           .Visible = True
      Do While ie.readyState <> READYSTATE_COMPLETE
      DoEvents
      Loop
      End With

      Set lists = html.getElementsByClassName("KambiBC-event-item__participants-container")

row = 1

     For Each ulElement In lists

       For Each liElement In ulElement.getElementsByClassName("KambiBC-event-participants")

       Set anchorElements = liElement.getElementsByClassName("KambiBC-event-participants__name")

          If anchorElements.Length > 0 Then
           Cells(row, 1) = anchorElements.Item(0).innerText
           row = row + 1
         End If
     Next liElement
     Next ulElement

   End Sub

Siddharth Rout · Accepted Answer · 2017-05-29 09:58:01Z

0

Error 424 is an Object Required Error. What is Html in Set lists = html.getElementsByClassName("KambiBC-event-item__participants-container")?

What you need is

Set lists = ie.document.getElementsByClassName("KambiBC-event-item__participants-container")

Code that I used

Sub useClassnames()
    Dim lists As IHTMLElementCollection
    Dim anchorElements As IHTMLElementCollection
    Dim ulElement As HTMLUListElement
    Dim liElement As HTMLLIElement
    Dim row As Long
    Dim ie As InternetExplorer

    Set ie = New InternetExplorer

    With ie
        .navigate "https://www.unibet.ro/betting#filter/all/all/all/all/in-play"
        .Visible = True

        Do While ie.readyState <> READYSTATE_COMPLETE
            DoEvents
        Loop
    End With

    Set lists = ie.document.getElementsByClassName("KambiBC-event-item__participants-container")

    row = 1

    For Each ulElement In lists
        For Each liElement In ulElement.getElementsByClassName("KambiBC-event-participants")
            Set anchorElements = liElement.getElementsByClassName("KambiBC-event-participants__name")

            If anchorElements.Length > 0 Then
                Cells(row, 1) = anchorElements.Item(0).innerText
                row = row + 1
            End If
        Next liElement
    Next ulElement
End Sub

Screenshot

edited May 29, 2017 at 9:58

answered May 28, 2017 at 20:26

Siddharth Rout

150k18 gold badges212 silver badges258 bronze badges

Sign up to request clarification or add additional context in comments.

7 Comments

Rius2 Over a year ago

I was trying to adapt the response from this thread <stackoverflow.com/questions/41851152/…> that seems to work to my needs. It gives me the same error .

Siddharth Rout Over a year ago

I just tried your above code which is posted in the question and it works for me :)

Siddharth Rout Over a year ago

yes :) I just replaced Html with ie.document in the code and it works for me

Rius2 Over a year ago

Interesant as it gave me the same error. Can you tell me what references have you used?

Siddharth Rout Over a year ago

1 Microsoft Internet Control 2 Microsoft HTML Object Library

|

Collectives™ on Stack Overflow

Web scraping with Excel and VBA

1 Answer 1

7 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

7 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related