ORA-00927: missing equal sign and bad bind variable errors from trigger

I doubt that storing number of messages for each type in separate table is good idea, You can always select such data. But if You insist please try something like this:

create or replace trigger actualiza_tb_mens_info
  after delete or insert or update on mensajes
  for each row

begin
  if inserting then

    merge into mensajes_info mi
    using (select :new.tipo tipo, :new.texto texto from dual) m
    on (mi.tipo = m.tipo)
    when matched then update set
      cuantos_mensajes = cuantos_mensajes + 1, ultimo = m.texto
    when not matched then
      insert (tipo, cuantos_mensajes, ultimo) values (m.tipo, 1, m.texto);

  elsif deleting then

    update mensajes_info set
        cuantos_mensajes = cuantos_mensajes - 1, ultimo = null
      where tipo = :old.tipo;

  elsif updating then
    if :old.tipo != :new.tipo then

      update mensajes_info set
          cuantos_mensajes = cuantos_mensajes - 1, ultimo = null
        where tipo = :old.tipo;

      merge into mensajes_info mi
      using (select :new.tipo tipo, :new.texto texto from dual) m
      on (mi.tipo = m.tipo)
      when matched then update set
        cuantos_mensajes = cuantos_mensajes + 1, ultimo = m.texto
      when not matched then
        insert (tipo, cuantos_mensajes, ultimo) values (m.tipo, 1, m.texto);

    else

      update mensajes_info set ultimo = :new.texto 
        where tipo = :new.tipo;

    end if;
  end if;
end;

When inserting use merge statement, when deleting correct update, when updating - it depends on whether type of message changes or not.

Test:

insert into mensajes (codigo, texto, tipo) values (1, 'Text 1', 'Type 1');
insert into mensajes (codigo, texto, tipo) values (2, 'Text 11', 'Type 1');  
insert into mensajes (codigo, texto, tipo) values (3, 'Text 12', 'Type 1');
insert into mensajes (codigo, texto, tipo) values (4, 'Text 21', 'Type 2');

delete from mensajes where codigo = 2;

update mensajes set tipo = 'Type 2' where codigo = 3;

select * from mensajes_info;

TIPO    CUANTOS_MENSAJES  ULTIMO
------  ----------------  --------------------
Type 1                 1  
Type 2                 2  Text 12

You have several issues in your code. The most pressing is that your update statements are malformed, as indicated by the ORA-00927: missing equal sign messages.

UPDATE MENSAJES_INFO SET(ULTIMO) SELECT :NEW.TEXT0 FROM ESC.MENSAJES;

is not valid; firstly you need an equals sign for the assignment as part of the update-set clause; secondly you do not select new/old pseudorecord values from their original table, you just refer directly to the :new.<column>: thirdly your table definition says the column name is texto not text0.

UPDATE MENSAJES_INFO SET ULTIMO = :NEW.TEXTO;

Similarly in the second update, you're missing an equals sign, and you can only set multiple values in parentheses with a subquery:

UPDATE MENSAJES_INFO SET CUANTOS_MENSAJES = CUANTOS_MENSAJES - 1, ULTIMO = NULL

Your third and fourth updates are presumably intended to update the message count for both kinds, and has similar other issues; the third is also goign to update all rows in the table, which isn't what you want, so you probably want something like:

IF(:OLD.tipo != :NEW.tipo) THEN
  UPDATE MENSAJES_INFO SET CUANTOS_MENSAJES = CUANTOS_MENSAJES - 1, ULTIMO = NULL
  WHERE :OLD.tipo = tipo;
END IF;
UPDATE MENSAJES_INFO SET CUANTOS_MENSAJES = CUANTOS_MENSAJES + 1, UNLTIMO = :NEW.TEXT0
WHERE :NEW.tipo = tipo;

So althogether, something more like:

CREATE OR REPLACE TRIGGER ACTUALIZA_TB_MENS_INFO 
AFTER DELETE OR INSERT OR UPDATE ON MENSAJES 
FOR EACH ROW
BEGIN
  IF INSERTING THEN
    UPDATE MENSAJES_INFO SET ULTIMO = :NEW.TEXTO;
  ELSIF DELETING THEN
    UPDATE MENSAJES_INFO SET CUANTOS_MENSAJES = CUANTOS_MENSAJES - 1, ULTIMO = NULL
    WHERE :OLD.tipo = tipo;
  ELSIF UPDATING THEN
    IF(:OLD.tipo != :NEW.tipo) THEN
      UPDATE MENSAJES_INFO SET CUANTOS_MENSAJES = CUANTOS_MENSAJES - 1, ULTIMO = NULL
      WHERE :OLD.tipo = tipo;
    END IF;
    UPDATE MENSAJES_INFO SET CUANTOS_MENSAJES = CUANTOS_MENSAJES + 1, ULTIMO = :NEW.TEXTO
    WHERE :NEW.tipo = tipo;
  END IF;
END;
/

I've also removed unnecessary parentheses. Read more about the update statement, triggers and pseudorecords.

Trying to maintain counts and other aggregate information via triggers can give you headaches though, as simultaneous operations against MENSAJES may leave the MENSAJES_INFO table in a state you don't expect unless access is serialised. A view over the base table would be simpler for the counts:

CREATE VIEW MENSAJES_INFO AS
SELECT TIPO, COUNT(*) AS CUANTOS_MENSAJES
FROM MENSAJES
GROUP BY TIPO;

... but that won't help with ULTIMO...