Get substring within a string

Question

I come to find some guidance on accomplishing the following:

I have a variable with content like this:

varname = asdfiuytgy12$gggsy22.oihbcxew

or

varname = oiujedc$thisisit.oiju

which $ and . are exactly my partters and I need to get what is within them so gggsy22 or thisisit.

I need to use batch to create a simple bat file. I hope someone can provide some guidance.

Edit - (from comment section)

Actually a friend of mine helped and it did work but with a quite amount of lines:

Set "sstr=$"
SET stemp=%nameVar%&SET pos=0

:loop
SET /a pos+=1
echo %stemp%|FINDSTR /b /c:"%sstr%" >NUL
IF ERRORLEVEL 1 (
    SET stemp=%stemp:~1%
    IF DEFINED stemp GOTO loop
    SET pos=0
)
Set "pos1=%pos%"
Set "sstr=."
SET stemp=%nameVar%&SET pos=0

:loop
SET /a pos+=1
echo %stemp%|FINDSTR /b /c:"%sstr%" >NUL
IF ERRORLEVEL 1 (
    SET stemp=%stemp:~1%
    IF DEFINED stemp GOTO loop
    SET pos=0
)
Set "pos2=%pos%"
set /a "pos2=%pos2%-%pos1%-1"
call set env=%%nameVar:~%pos1%,%pos2%%%

What have you tried so far, where are you stuck? Type set /? and for /? into a command prompt window and read the help texts very carefully; I'm sure you'll find something helpful... — aschipfl
– aschipfl, Commented Jul 4, 2017 at 16:50
Actually a friend of mine helped and it did work but with a quite amount of lines: — KP73
– KP73, Commented Jul 4, 2017 at 19:18
Please include the code in your question as it is not readable in a comment... — aschipfl
– aschipfl, Commented Jul 4, 2017 at 21:09
That code in your Edit cannot possibly work. The logic is wrong, and your use of duplicate :label names will result in unwanted loop cross pollination. — dbenham
– dbenham, Commented Jul 5, 2017 at 15:22

Stephan · Accepted Answer · 2017-07-04 16:48:28Z

3

@echo off
set "varname=asdfiuytgy12$gggsy22.oihbcxew"
for /f "tokens=2 delims=$." %%a in ("%varname%") do set "sub=%%a"

answered Jul 4, 2017 at 16:48

Stephan

56.8k11 gold badges66 silver badges97 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

dbenham Over a year ago

This would give an erroneous result with a string like abc$123$xyz or abc.123.xyz or abc$123 or abc.123.

dbenham Over a year ago

This would also fail with a string like abc$.xyz

dbenham · Accepted Answer · 2017-07-05 05:52:05Z

1

The following works in nearly any situation. The only thing that could break the code is if the string contains a quote " followed by a poison character like &, |, etc.

@echo off
setlocal
set "str=oiujedc$thisisit.oiju"

:: Verify string exists and has the proper format
echo "%str%"|findstr "\$.*\." >nul || (echo Value not found & exit /b)

:: Extract the value
:: The extra "x" is needed in case there is no character between $ and .,
:: in which case the result should be No Value (result variable not defined)
for /f "delims=." %%A in ("x%str:*$=%") do set "val=%%A"
set "val=%val:~1%"

:: Show the result
echo value = "%val%"

A bullet proof variant can be made by incorporating delayed expansion.

answered Jul 5, 2017 at 5:52

dbenham

132k29 gold badges273 silver badges410 bronze badges

4 Comments

user6811411 Over a year ago

Wouldn't the first check be more exact/easier with findstr "\$..*\." >nul or findstr "\$[^$.][^$.]*\." >nul ?

user6811411 Over a year ago

Your comment seems off track as this is about strings with $ and . not files with an underscore. Your above code will return wrong results with (of course construed) strings like "oiujedc$a$thisisit.oiju" , "oiujedc$.a$thisisit..oiju" or "oiujedc$$thisisit..oiju"

dbenham Over a year ago

@LotPings - Sorry, my head was in the wrong (totally unrelated) Q&A when I wrote my (deleted) comment. I'm back on topic :-) I am assuming that an empty string from xxx$.xxxx is a valid result, but a source string without $ and or . is invalid, which is why I did not use your first regex. I wanted to be able to differentiate between the two scenarios. If no need to differentiate, then i like your first regex. As to whether my results are wrong with your construed strings, that is debatable. The OP did not specify how to handle multiple $ and/or ..

dbenham Over a year ago

@LotPings - My code consistently handles multiple $ or . in a reliable way. I begin extracting immediately after the first occurrence of $, and stop at the next occurrence of .. My code allows $ to be in the resultant value.

Collectives™ on Stack Overflow

Get substring within a string

2 Answers 2

2 Comments

4 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

4 Comments

Your Answer

Sign up or log in

Post as a guest

Related