How to sort nodes of XML with XSLT

Question

There is given order of nodes and I need to sort the nodes of XML according to the given order. The input is a XML file and output is the XML file with nodes ordered according to given list.

XML:

<root>
    <M node="C" home="zzz"/>
    <X name="A"/>
    <Z/>
    <Y test="B"/>    
</root>

XSLT:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pSortingValues" select="'Y,X,Z,M,N'"/>
 <xsl:variable name="vSortingValues" select=
  "concat(',', $pSortingValues, ',')"/>

    <xsl:template match="node()|@*">
      <xsl:copy>
       <xsl:apply-templates select="node()|@*">
        <xsl:sort data-type="number" select=
        "string-length(substring-before($vSortingValues,concat(',',name,',')))"/>
       </xsl:apply-templates>
      </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Received Output:

<root>
  <M node="C" home="zzz"/>
  <X name="A"/>
  <Z/>
  <Y test="B"/>
</root>

Desired Output:

<root>
 <Y test="B"/>
 <X name="A"/>
 <Z/>
 <M node="C" home="zzz"/>        
</root>

The above XSLT currently only parses the XML without sorting in the required order of nodes: 'Y,X,Z,M,N'.

Tim C · Accepted Answer · 2017-08-30 07:50:00Z

2

You are trying to sort by node name, but the expression name is looking for an element called "name". You need to use name() to get the name of the node

<xsl:sort data-type="number" select="string-length(substring-before($vSortingValues,concat(',', name(),',')))"/>

Note, for future reference, you can also use local-name() here. name() would include any namespace prefix, should namespaces be involved, whereas local-name() returns the name without any prefix.

edited Aug 30, 2017 at 7:50

answered Aug 29, 2017 at 14:54

Tim C

70.7k14 gold badges77 silver badges94 bronze badges

Sign up to request clarification or add additional context in comments.

Collectives™ on Stack Overflow

How to sort nodes of XML with XSLT

1 Answer 1

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

Comments

Your Answer

Sign up or log in

Post as a guest

Related