Convert constructor in record to custom json string in aeson haskell

Question

I would like to convert my json to below format. And to convert from below format to my record. Please check the code that I have written below.

{
    "uid" : "bob",
    "emailid" : "[email protected]",
    "email_verified" : "Y" // "Y" for EmailVerified and "N" for EmailNotVerified
}

I have below code where I am trying to convert user type to and from json using Aeson library in Haskell

{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE DeriveGeneric #-}

import Data.Monoid ((<>))
import GHC.Generics
import Data.Aeson (FromJSON, ToJSON)
import Data.Aeson.Types

data User = User {
    userId :: String,
    userEmail :: String,
    userEmailVerified :: EmailState
  } deriving (Show, Generic)

data EmailState = EmailVerified | EmailNotVerified deriving (Generic, Show)

instance ToJSON User where
    toJSON u = object [
       "uid" .= userId u,
       "emailid" .= userEmail u,
       "email_verified" .= userEmailVerified u
       ]

instance FromJSON User where
    parseJSON = withObject "User" $ \v -> User
        <$> v .: "uid"
        <*> v .: "emailid"
        <*> v .: "email_verified"

instance ToJSON EmailState
instance FromJSON EmailState

However, My format that I am currently able to generate is like below

{
    "uid" : "bob",
    "emailid" : "[email protected]",
    "email_verified" : "EmailVerified"
}

You should also implement To/FromJSON instances for EmailState — 4e6
– 4e6, Commented Nov 27, 2017 at 10:40

willeM_ Van Onsem · Accepted Answer · 2017-11-27 10:52:36Z

5

You need to implement the ToJSON of EmailState yourself (so remove the instance ToJSON EmailState, and write it like):

instance ToJSON EmailState where
    toJSON EmailVerified = String "Y"
    toJSON EmailNotVerified = String "N"

You also will need to alter yhe parser:

instance FromJSON EmailState where
    parseJSON (String "Y") = return EmailVerified
    parseJSON (String "N") = return EmailNotVerified
    parseJSON _ = fail "Invalid JSON value to parse"

edited Nov 27, 2017 at 10:52

answered Nov 27, 2017 at 10:46

willeM_ Van Onsem

482k33 gold badges483 silver badges624 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

navin Over a year ago

Thanks Willem . Your solution does work . If possible can you also update your answer or point to a good resource so that a new comer to haskell like me can understand hackage documentation. Like in above case I was trying instance ToJSON EmailState where toJSON _ = "Y" which did not work obviously.

Ishmum Khan · Accepted Answer · 2018-10-29 15:04:04Z

0

Awesome answer by Willem, Just to add to the syntax you can use -

instance FromJSON EmailState where
    parseJSON (String s) 
        | s == "Y" = return EmailVerified
        | s == "N" = return EmailNotVerified
        | otherwise = fail "Invalid JSON value to parse"

-- Note: otherwise = mzero -- is prefered

ref: https://mail.haskell.org/pipermail/beginners/2011-October/008791.html

answered Oct 29, 2018 at 15:04

Ishmum Khan

11 bronze badge

Collectives™ on Stack Overflow

Convert constructor in record to custom json string in aeson haskell

2 Answers 2

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related