batch file, string manuplutation with dir command

Question

Trying to get this to work.

Getting this line from dir: 3 File(s) 7,332,731,128 bytes and trying to just get the number of files to use for addition.

@Echo ON

dir %1 /a:h | find "File(s)" > hidden.txt
dir %1 | find "File(s)" > reg.txt

set /p hidden=<hidden.txt
echo %hidden%
IF /I "%hidden%"=="File Not Found" (
    Set hidden = 0
    ) Else (
Set hidden=%hidden~-29%)

echo %hidden%
Set /p reg=<reg.txt
IF /I "%hidden%"=="File Not Found" (
    set reg = 0
    ) ELSE (
    Set reg=%reg~-29%)
set /a total = %reg% + %hidden%

Echo The total number of files in the %1 directory is: %total%. This includes hidden files.
Echo.
Echo The total number of non-hidden files in the %1 directory is: %reg%.
Echo.
Echo The total number of hidden files in the %1 directory is: %hidden%

You can use a FOR /F command to either read the output file you created or parse the output of the DIR and FIND commands. By default the output will be split by the first space. So you can assign the FOR variable to an environmental variable to use later in your script. — Squashman
– Squashman, Commented Dec 12, 2017 at 16:45
A better option would be to use the /C option of the FIND command to count the number of files. dir "%1"/a:h-d /b|find /c /v "" — Squashman
– Squashman, Commented Dec 12, 2017 at 16:49

npocmaka · Accepted Answer · 2017-12-12 16:53:06Z

1

you don't need temp files which only will slow down your script:

if you want to count the hidden files try this

@echo off
set counter=0
for /f %%# in ('dir /a:h-d "%~1"') do (
  set /a counter=counter+1
)
echo hidden files=%counter%

to count all files

@echo off
set counter=0
for /f %%# in ('dir /a:-d "%~1"') do (
  set /a counter=counter+1
)
echo all files=%counter%

answered Dec 12, 2017 at 16:53

npocmaka

57.8k19 gold badges162 silver badges199 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Compo · Accepted Answer · 2017-12-12 17:28:25Z

1

This is just another For loop option:

@For /F %%A In ('Dir/AH-D-L "%~1" 2^>Nul') Do @If Not "%%A"=="0" Set "fileCount=%%A"
@Echo %fileCount%
@Pause

Remove -L, if you wish not to exclude junction points from your file count.

answered Dec 12, 2017 at 17:28

Compo

39k5 gold badges32 silver badges46 bronze badges

Comments

Fran Moreno · Accepted Answer · 2017-12-14 02:29:43Z

I've got the same result with just two FOR loops. Using sentences between single quotes inside the parentheses we can execute commands and store results.

I've left the same Result Text just to let you compare and see if this is what you're looking for:

CODE:

@echo off
setlocal

for /f %%A in ('dir "%~1" /a-h-d /b ^| find /V /C ""') do set "visCount=%%A"
for /f %%A in ('dir "%~1" /ah-d /b ^| find /V /C ""') do set "hidCount=%%A"

set /a totalCount = visCount + hidCount

echo.
echo The total number of files in the %1 directory is: %totalCount%. This includes hidden files.
echo.
echo The total number of non-hidden files in the %1 directory is: %visCount%.
echo.
echo The total number of hidden files in the %1 directory is: %hidCount%

With /B parameter of DIR command I only get one line per file and no more text, and with /A I can select Hidden or not files and no directories.

Then SET /A command let us use arithmetics operations.

Collectives™ on Stack Overflow

batch file, string manuplutation with dir command

3 Answers 3

Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related