Replace string in a file with a specific field value from another file with awk

Question

My file1 looks like:

bla bla bla STRING_1 blabla STRING_2.
bla bla bla bla bla.

My file2 looks like (tab-separated):

FILENAME   FIELD_1   FIELD_2
out1   ABCDEF   GHIJKL
out2   MNOPQR   STUVWX

I am trying to replace STRING_1 and STRING_2 from file1 with the corresponding fields from file2, and output 2 different files with their name as below:

out1:

bla bla bla ABCDEF blabla GHIJKL.
bla bla bla bla bla.

out2:

bla bla bla MNOPQR blabla STUVWX.
bla bla bla bla bla.

What I tried:

awk -F '\t' '
NR==FNR{
   if(NR>1){
      a[NR]=$1
      b[NR]=$2
      c[NR]=$3
      next
   }
}
{
   for(i=1; i<=FNR; i++){
      gsub(/STRING_1/,bi])
      gsub(/STRING_2/,c[i])
      print $0 > a[i]
   }
}
' file2.tab file1.tab

This command only creates a file "FILENAME" that contains the following:

bla bla bla FIELD_1 blabla FIELD_2.
bla bla bla bla bla.

Any help would be appreciated. Thanks !

NOTE: file1 is a unique template file for which the content does not change.

Ed Morton · Accepted Answer · 2018-01-29 16:19:55Z

1

Here's how to implement your approach of using gsub()s, untested:

awk '
NR==FNR {
    if (NR>1) {
        files[$1]
        for (i=2; i<=NF; i++) {
            map[$1,i-1] = $i
        }
    }
    next
}
{
    for (file in files) {
        rec = $0
        gsub(/STRING_1/,map[file,1],rec)
        gsub(/STRING_2/,map[file,2],rec)
        print rec > file
    }
}
' file2 file2

Note that this approach will have problems if STRING_1, etc. can contain regexp metacharacters, or if the replacement ones can contain backreferences (&), or if partial matches are possible (the replaced within then). You may also need to close() the output files as you go and use >> to write to them if you have many output files and aren't using GNU awk.

edited Jan 29, 2018 at 16:19

answered Jan 29, 2018 at 15:36

Ed Morton

209k18 gold badges90 silver badges212 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

RomanPerekhrest · Accepted Answer · 2018-01-29 16:12:04Z

0

GNU awk solution:

awk 'NR==FNR{ 
         if (NR==1) next;
         c=0; f[$1][++c]=$2; f[$1][++c]=$3; next 
     }
     { 
         c=0;
         for (i in f) { 
             b[++c]=$0; 
             gsub(/STRING_1/, f[i][1], b[c]); 
             gsub(/STRING_2/, f[i][2], b[c]); 
             print b[c] > i 
         }
     }' file2 file1

f[$1][++c] - multidimensional array f where $1 is a parent key (for ex. out1) and ++c points to ordinal field number (i.e. 1 and 2)
for (i in f) - iterating through output filenames

Viewing results:

$ head out[12]
==> out1 <==
bla bla bla ABCDEF blabla GHIJKL.
bla bla bla bla bla.

==> out2 <==
bla bla bla MNOPQR blabla STUVWX.
bla bla bla bla bla.

edited Jan 29, 2018 at 16:12

answered Jan 29, 2018 at 16:05

RomanPerekhrest

93.1k4 gold badges75 silver badges112 bronze badges

2 Comments

RomanPerekhrest Over a year ago

@EdMorton, try without it and you'll see

Ed Morton Over a year ago

No, that's fine, I don;t care enough to try it.

Collectives™ on Stack Overflow

Replace string in a file with a specific field value from another file with awk

2 Answers 2

Comments

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related