Adding zero to part of string using sed

The MAC address is colon-separated. You can use that to limit the substitutions. This will perform the substitutions that you are interested in but only if the word character is next to a colon:

sed -e 's/\b\w:/0&/g; s/:\(\w\)\b/:0\1/g'

For example:

$ echo IP-MIB::ipNetToMediaPhysAddress.5122.192.19.3.25 = STRING: 34:8:4:56:f4:70  | sed -e 's/\b\w:/0&/g; s/:\(\w\)\b/:0\1/g'
IP-MIB::ipNetToMediaPhysAddress.5122.192.19.3.25 = STRING: 34:08:04:56:f4:70

How it works

• s/\b\w:/0&/g

  This performs the substitution if the word character is preceded by a word break, \b, and followed by a colon. Since we just need to put a zero in front of the entire matched text, not just some section of it, we can omit the parens and just use & to copy the matched text.

• s/:\(\w\)\b/:0\1/g

  If there are any remaining substitutions that need to be done where the word character is preceded by a colon and followed by a word break, this does them.

Note: We are using GNU extensions that may not be portable.

Another way with sed if the MAC address is at end of line

echo IP-MIB::ipNetToMediaPhysAddress.5122.192.19.3.25 = STRING: 4:8:d:56:f4:7 |
sed -E '
s/$/:/
:A
s/([^[:xdigit:]])([[:xdigit:]]:)/\10\2/
tA
s/:$//'