SAS:how to use index to pick out macro array variable

You do not create an array with your select. The result is just a string: var1 var2 var3

However you can access each element with the scan-function:

%let first_ele = %scan(&numVarList.,1,%str( ));

The result is: var1

You can also loop your string like this:

%do i=1 %to %sysfunc(countw(&numVarList.,%str( )));
   %put %scan(&numVarList.,&i.,%str( ));
%end;

Concatenation of values

proc sql;
select distinct variable into:numVarList separated by ' ' from Map_num;

populates a single macro variable with a value, that can be construed as a list, which is a concatenation of the distinct values in the column named "variable".

For such a list you would scan out the individual items as shown by @zuluk.

In your case when the original values are names of variables, the resolution of the concatenation can be used directly as part of a SAS statement that accepts variable name lists, such as Proc PRINT; VAR &numVarList or DATA _NULL_; ARRAY v &numVarList

Macro array

The concept macro-array is simply a set of macro variables (which can be thought of as 'symbols' when too many 'variable' ideas are colliding) with a common basename and increasing numeric suffix. Such a set of macro variables is created by using a slightly different syntax in Proc SQL.

select distinct variable
into :symbol1-:symbol9999
from Map_num

The 9999 represents a large number that you do not expect to exceed. If the data has N <= 9999 rows then only N macro variable will be created. If N > 9999 rows only 9999 macro variables will be created. Caution: Too many macro variables can fill the macro symbol table and cause errors in your SAS. For me, Macro arrays are more a programming concept than a programming construct.

For example

Proc SQL noprint;
  select name into :name1-:name9999 from sashelp.class;
  %let name_count = &sqlobs;
quit;

%put NOTE: &=name1;
%put NOTE: &=name2;
%put NOTE: name&name_count=%superq(name&name_count);  * almost same as next;
%put NOTE: name&name_count=&&name&name_count;    * almost same as prev;

When dealing with the 'name' of the macro array in 1-level abstraction way, complete resolution is achieved by coding the 'tricky triple-hat' &&&

%macro log_macroArray (basename);
   %local i count_symbol value_symbol;
   %let count_symbol = &basename._count;

   %do i = 1 %to &&&count_symbol;
     %let value_symbol = &basename.&i;
     %put NOTE: &value_symbol=&&&value_symbol;
   %end;
%mend;

%log_macroArray(name);

The SAS macro system 'loops' internally during its value resolution phase and collapses the presence to && to & at each step of it's internal evaluation.

Building on @zuluk's answer, you cannot use an operator (like { }) to access a macro "array" since it's not a part of the language and it's not possible to overload operators in SAS... mostly ... but you can do a function-style macro easily.

proc sql;
  select name into :namelist separated by ' '
  from sashelp.class;
quit;
%macro marray(list, n);
  %scan(&list.,&n.)
%mend marray;

%put %marray(&namelist,2);

That is pretty close to what you're looking for, just not quite the same syntax. If you then wanted to build new variables/etc., you could do so through the macro as well, though it might be more complicated to write a general macro given there are lots of ways you might want to do that. Here's a non-function-style version.

%macro m_to_array(list, n);
  *optionally - if you want to not specify n;
  %let n = %sysfunc(countw(&&&list));
  %do _i = 1 %to &n;
    %global &list.&_i.;
    %let &list.&_i. = %scan(&&&list.,&_i.);
  %end;
%mend m_to_array;

%m_to_array(namelist);
%put _global_;