SAS set into array values from table

Question

Thanks user667489. Perhaps I think good.. But now I have problem with merge methods...

data Dictionary;
   input id_wiersz Labely $20. ;
   datalines;                      
1 Active
2 Gold
3 Prime
;

*Get the array parameter;
proc sql noprint;
select count(1) into :reccount from work.Dictionary ;
quit;

proc transpose data = Dictionary out = Dictionaryout;
    var Labely;
run;

data ArraryLoaded;
    set Dictionaryout (drop=_name_) nobs = nobs;
    array Dictionary _CHAR_;
    format col1-col3 $50.;
    retain col1-col3;
    array t[&reccount] $;
    do i = 1 to dim(t);
        if _N_ = 1 then t[i] = put(Dictionary[i], 8.);
            else t[i] = compress(t[i] || ',' || put(Dictionary[i], 8.));
    end;
    if _N_ = nobs;
    put "var1," t1;
    put "var2," t2;
    put "var3," t3;
run;

data Scinamy;
   input Description $20. ;
   datalines;                      
New old Active
New Active Old
ANother record
Records with Gold
Value with Gold
;

How to lista(&reccount) insert array t[&reccount]?

data Scinamy1;
  set Scinamy;
  array lista(&reccount) $8 _temporary_ ('Active','Gold','Prime');
  length AA $30 ;
  do i = 1 to dim(lista);
    if findw(Description,lista(i),,'spit') then AA=catx(' ',AA,lista(i));
  end;
  if missing(AA) then AA='Not Found';
  drop i;
run;

Hey Tom, In step "data ArraryLoaded"'I loaded values to array from table. And I need use this array to next step - data Scinamy1; - i want use array from Data ArraryLoaded instead "array lista(&reccount) $8 _temporary_ ('Active','Gold','Prime'); from data Scinamy1; — DarkousPl
– DarkousPl, Commented Jun 21, 2018 at 7:02

user667489 · Accepted Answer · 2018-06-20 09:34:40Z

1

I can think of a few options that you could explore:

Replace each distinct value of Labely with a different integer and define a format to display the corresponding values. Then you can use your existing write_array approach.
Define and populate a character array within a data step using a do-loop.
Use a hash object to hold your dictionary instead of an array, and loop through it using a hash iterator.

Have a go at one of these and post another question if you get stuck.

answered Jun 20, 2018 at 9:34

user667489

9,5872 gold badges28 silver badges38 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Tom · Accepted Answer · 2018-06-21 14:11:13Z

0

If you want to use the data from your small table to generate a temporary array in a future data step you could use the SAS macro processor to help you generate the statement.

If the list is small enough to fit into a single macro variable (64K characters) then you could use something like this:

proc sql noprint;
  select quote(trim(LabelY)) into :Label_list separated by ' '
  from work.dictionary;
%let no_labels=&sqlobs;
quit;

data new_step ;
   array lista(&no_labels) $20 _temporary_ (&label_list) ;
....

Watch out because dictionary is a special libref in PROC SQL. Prefixing with work. should make it work. Or just name the dataset something else.

But it might just be easier to use the original dataset instead of an ARRAY.

data Scinamy1;
  set Scinamy;
  length AA $30 ;
  do i = 1 to nobs;
    set work.dictionary(keep=LabelY) point=i nobs=nobs;
    if findw(Description,LabelY,,'spit') then AA=catx(' ',AA,LabelY);
  end;
  if missing(AA) then AA='Not Found';
  drop LabelY ;
run;

answered Jun 21, 2018 at 14:11

Tom

52.3k2 gold badges19 silver badges36 bronze badges

1 Comment

DarkousPl Over a year ago

Excellent! Both methods works great, and I understood two new methods processing :)

Collectives™ on Stack Overflow

SAS set into array values from table

2 Answers 2

Comments

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related