Rendering bitstring from phoenix view

Question

I have a bitstring of the form bitstring = <<18::6,8::4,2::5,16::5,18::6,3000::16,0::4>>. I want to render but poison or Jason doesn't seem to be rendering. What is the best way to render a bitstring in response like this.

Something like this

bits = <<18::6,8::4,2::5,16::5,18::6,3000::16,0::4>>
render(conn, "bits.json", bits: bits)

What do you mean by render? JSON doesn't have a binary data type. What's your expected JSON value? — Dogbert
– Dogbert, Commented Aug 3, 2018 at 11:13
So I need to convert into a valid bitstring? How do I convert this into a valid bistring so that it can be parsed again into binary — Tanweer
– Tanweer, Commented Aug 3, 2018 at 11:31
What JSON value are you expecting for this? An array of bytes? or perhaps Base64 encoded string? — Dogbert
– Dogbert, Commented Aug 3, 2018 at 12:35

Dogbert · Accepted Answer · 2018-08-03 14:27:38Z

2

If the goal is to encode and then later decode the bitstring, and efficiency of storage is a concern, I'd go with converting the bitstring to a binary using term_to_binary and then encoding it as a base-64 string. This will give you a nice compact representation of the bitstring that can later be decoded.

defmodule A do
  def encode(bitstring) when is_bitstring(bitstring) do
    bitstring |> :erlang.term_to_binary() |> Base.encode64
  end

  def decode(binary) do
    decoded = binary |> Base.decode64!() |> :erlang.binary_to_term([:safe])
    if is_bitstring(decoded), do: decoded, else: nil
  end
end

IO.inspect encoded = A.encode(<<0::220>>)
IO.inspect A.decode(encoded)

Output:

"g00AAAAcBAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA="
<<0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0,
  0, 0::size(4)>>

You can pass the output of A.encode to your JSON encoder and call A.decode after decoding using the JSON decoder.

answered Aug 3, 2018 at 14:27

Dogbert

224k43 gold badges419 silver badges416 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Tanweer Over a year ago

This answer is perfect

Aleksei Matiushkin · Accepted Answer · 2018-08-03 13:35:53Z

1

One cannot convert 46 bits into byte array. AFAICT, there are two most natural options here.

One might use the array with a binary representation of the value:

for << <<c::1>> <- <<18::6,8::4,2::5,16::5,18::6,3000::16,0::4>> >>, do: c    
#⇒ [0, 1, 0, 0, 1, 0, 1, 0, 0, 0, 0, 0, 0, 1, 0, 1, 0, 0, 0, 0, 0, 1, 0, 0, 1, 0,
#   0, 0, 0, 0, 1, 0, 1, 1, 1, 0, 1, 1, 1, 0, 0, 0, 0, 0, 0, 0]

or one might use the binary with the above joined:

(for << <<c::1>> <- <<18::6,8::4,2::5,16::5,18::6,3000::16,0::4>> >>, do: c)
|> Enum.join()
#⇒ "0100101000000101000001001000001011101110000000"

answered Aug 3, 2018 at 13:35

Aleksei Matiushkin

121k12 gold badges109 silver badges174 bronze badges

Collectives™ on Stack Overflow

Rendering bitstring from phoenix view

2 Answers 2

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related