Add strings into .txt file using batch file

Question

I have a file with records that looks like the following:

Aaron,Daniel,,,AARDA,MEDICAL,10,HEH

I need a batch file that can look to the correct comma and insert quotes as well as add a comma to the end of the file.

I have this batch file which successfully adds quotes to the beginning of each line:

@echo
setLocal EnableDelayedExpansion
for /f "tokens=* delims= " %%a in (input.txt) do (
set /a N+=1
echo ^"%%a >>output.txt
)

What I need is for the output to look like:

"Aaron,Daniel,,",AARDA,MEDICAL,10,HEH,

Due to the requested output it will always be between the 3rd and 4th comma on every line. — mslhrt
– mslhrt, Commented Sep 12, 2018 at 15:24
Is there a chance that you have more one instance of 3 consecutive commas in each line? or it occurs only once in each line? — sst
– sst, Commented Sep 12, 2018 at 15:30
Hopefully I'm answering your question, the 3 consecutive commas on each line are blank placeholders for each record and will be consistent throughout the whole file. — mslhrt
– mslhrt, Commented Sep 12, 2018 at 15:32

sst · Accepted Answer · 2018-09-12 15:53:20Z

2

As I understood from the comment under your question, the 3 consecutive commas occurs only once in each line. For that matter the solution is extraordinary simple:

@echo off 
setlocal DisableDelayedExpansion
(
    for /F "usebackq tokens=*" %%A in ("input.txt") do (
        set "Line=%%A"
        setlocal EnableDelayedExpansion
        echo "!Line:,,,=,,",!,
        endlocal
    )
)>"output.txt"

It initially starts with delayed expansion off and enables delayed expansion at each iteration of the loop to prevent corrupting lines that contain the ! character.

Since the ,,, occurs only once in each line (As I understood) it can be safely replaced by ,,",

tokens=* is only needed if you want to remove the possible leading white spaces from each line, otherwise you can just use "delims=" to read the whole line in to a single token.

answered Sep 12, 2018 at 15:53

sst

1,4731 gold badge13 silver badges15 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

9bO3av5fw5 · Accepted Answer · 2018-09-12 16:52:57Z

1

If an alternative approach is of interest.

With sample file test.txt:

Aaron,Daniel,,,AARDA,MEDICAL,10,HEH
Bob,Edward,,,AARDA,MEDICAL,10,HEH

Using sed, replace the 4th comma with ", and add " at the beginning (^) and , at the end ($):

sed 's/,/",/4' test.txt | sed 's/^/"/' | sed 's/$/,/'

Returns:

"Aaron,Daniel,,",AARDA,MEDICAL,10,HEH,
"Bob,Edward,,",AARDA,MEDICAL,10,HEH,

answered Sep 12, 2018 at 16:52

9bO3av5fw5

1,0058 silver badges15 bronze badges

Collectives™ on Stack Overflow

Add strings into .txt file using batch file

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related