TStringList for loop

Question

Here its a VCL app and I have a link with my Ini file and I wanna keep adding lines in there with time and date stamps with press of a button.

private
  FLog: TStringList;
  FIni: TIniFile;
  aTime: TDateTime;

procedure TForm2.btnBreakClick(Sender: TObject);
begin
  FLog := TStringList.Create;
  try
    aTime := Now;
    begin
      FIni.WriteString('FileName', 'Break', FormatDateTime('dd/mm/yyyy hh:nn', aTime));
    end;
  finally
    FLog.Free;
  end
end;

With this piece of code I can only replace the previous time and date stamp I have tried to do it with a for loop but without succes.

This is the outcome with the current few lines of code.

[FileName]
Break=09-10-2018 13:35

And what I want is that everytime I hit the break button it needs to add on to the file with a other time.

INI files have sections denoted by a name in square brackets and key+value pairs. If you want multiple values you need to use multiple unique keys. Like Break.1, Break.2 etc. — Brian
– Brian, Commented Oct 9, 2018 at 13:00
@Brian, or let the value part be an array of strings, separated with a delimiter. — LU RD
– LU RD, Commented Oct 9, 2018 at 13:07
@MBo I have multiple buttons and want everything in a list and read it out in a Tmemofield and havent found a other method there probaly is one but havent found it — Noisse
– Noisse, Commented Oct 9, 2018 at 13:23
We can't readily give you code because we don't understand your question. You have a string list that you do nothing with, and an ini file that behaves as designed. Your title asks about the string list but you do absolutely nothing with the string list, beyond creating it and destroying it — David Heffernan
– David Heffernan, Commented Oct 9, 2018 at 13:49

Remy Lebeau · Accepted Answer · 2018-10-09 14:58:57Z

An INI file contains key/value pairs. To do what you are asking for, you need to create a unique key name with every button press, otherwise you are just overwriting an existing value each time, as you have already discovered.

Try something more like this:

procedure TForm2.btnBreakClick(Sender: TObject);
var
  Keys: TStringList;
  MaxBreak, I, Num: Integer;
begin
  MaxBreak := 0;
  Keys := TStringList.Create;
  try
    FIni.ReadSection('FileName', Keys);
    for I := 0 to Keys.Count-1 do
    begin
      if StartsText('Break', Keys[I]) then
      begin
        if TryStrToInt(Copy(Keys, 6, MaxInt), Num) then
        begin
          if Num > MaxBreak then
            MaxBreak := Num;
        end;
      end;
    end;
  finally
    Keys.Free;
  end;
  FIni.WriteString('FileName', 'Break'+IntToStr(MaxBreak+1), FormatDateTime('dd/mm/yyyy hh:nn', Now));
end;

Or this:

procedure TForm2.btnBreakClick(Sender: TObject);
var
  I: Int64;
  Key: string;
begin
  for I := 1 to Int64(MaxInt) do
  begin
    Key := 'Break' + IntToStr(I);
    if not FIni.ValueExists('FileName', Key) then
    begin
      FIni.WriteString('FileName', Key, FormatDateTime('dd/mm/yyyy hh:nn', Now));
      Exit;
    end;
  end;
end;

Or this:

procedure TForm2.btnBreakClick(Sender: TObject);
var
  NumBreaks: Integer;
begin
  NumBreaks := FIni.ReadInteger('FileName', 'NumBreaks', 0);
  Inc(NumBreaks);
  FIni.WriteInteger('FileName', 'NumBreaks', NumBreaks);
  FIni.WriteString('FileName', 'Break' + IntToStr(NumBreaks), FormatDateTime('dd/mm/yyyy hh:nn', Now));
end;

Tom Brunberg · Accepted Answer · 2018-10-09 17:01:18Z

1

Although you referred to TIniFile, your post and your comments tell me that that is not necessarily what you want. TIniFile is not really intended for the kind of usage you are describing, although it can be used (as the other answer shows).

For simple recording of events I suggest an ordinary text file, and for adding events to it, a TStringList as in the following example. The example is a simplified extract from code I used myself long time ago.

var
  EventFile: TFileName;

procedure EventRecorder(EventTime: TDateTime; Description, Comment: string);
var
  sl: TStringList;
  es: string;
begin
  sl: TStringList;
  try
    if FileExists(EventFile) then
      sl.LoadFromFile(EventFile);
    es := FormatDateTime('yyyy-mm-dd hh:nn:ss', EventTime)+' '+Description+' '+comment;
    sl.Add(es);
    sl.SaveToFile(EventFile);
  finally
    sl.free;
  end;
end;

Typical usage

procedure TForm2.btnBreakClick(Sender: TObject);
begin
  EventRecorder(now, 'Break', '');
end;

answered Oct 9, 2018 at 17:01

Tom Brunberg

21.2k8 gold badges43 silver badges58 bronze badges

3 Comments

Jerry Dodge Over a year ago

Pretty heavy for appending to the end. This is one of the rare cases where TextFile type is probably a good idea.

Tom Brunberg Over a year ago

@Jerry You are probably/possibly right. I dropped it from my toolbox with the new millenium festives ;)

Rudy Velthuis Over a year ago

@Jerry: or a simple stream. One can easily append using streams too, even text.

Collectives™ on Stack Overflow

TStringList for loop

2 Answers 2

Comments

3 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

3 Comments

Your Answer

Sign up or log in

Post as a guest

Related