Call system command from perl script printing the output AND storing it into a variable

Question

I want to send a command, for example, execute a ping:

ping google.es -n 500

I can execute the command with:

my $command =  "ping google.es -n 500";
system($command);

And I will get the output printed while it runs.

I can store it into a variable with:

my $command =  "ping google.es -n 500";
my $output = `$command`;

But how can I get the output of the command WHILE it is running and then use the output in a variable?

I´ve see a solution like this, but it does not work. It runs the script and when it has finished it will print the result:

my $variable = '';
open my $command_pipe, "-|", $command or die "Pipe from $command failed: $!";
while (<$command_pipe>) {
    print  $_;
    $variable . = $_;
}

UPDATE: Example to show the problem. I have 2 perl scripts and one calls the other:

test.pl:

use strict;
use warnings;

my $command = 'perl test2.pl';

print "Localtime: " . localtime() . "\n";

my $variable = '';
open my $command_pipe, "-|", $command or die "Pipe from $command failed: $!";
while (<$command_pipe>) {
    print "[" .  localtime() . "] " . $_;
    $variable .= $_;
}

print "Localtime: " . localtime() . "\n";
print "Loop finished:\n$variable\n";

Second file test2.pl:

use strict;
use warnings;


print "Waiting 10 sec\n";
my $i = 0;
while($i < 10){
    sleep(1);
    print "$i\n";
    $i++;
}
print "That's it!\n";

And the output is:

C:\Users\****\Desktop\****>perl test.pl
Localtime: Wed Oct 17 13:47:06 2018
[Wed Oct 17 13:47:16 2018] Waiting 10 sec
[Wed Oct 17 13:47:16 2018] 0
[Wed Oct 17 13:47:16 2018] 1
[Wed Oct 17 13:47:16 2018] 2
[Wed Oct 17 13:47:16 2018] 3
[Wed Oct 17 13:47:16 2018] 4
[Wed Oct 17 13:47:16 2018] 5
[Wed Oct 17 13:47:16 2018] 6
[Wed Oct 17 13:47:16 2018] 7
[Wed Oct 17 13:47:16 2018] 8
[Wed Oct 17 13:47:16 2018] 9
[Wed Oct 17 13:47:16 2018] That's it!
Localtime: Wed Oct 17 13:47:16 2018
Loop finished:
Waiting 10 sec
0
1
2
3
4
5
6
7
8
9
That's it!

As you can see everything is just printed after the 10 seconds of the second script.

Dave Cross · Accepted Answer · 2018-10-17 12:37:53Z

6

This code works exactly as expected for me (I changed the syntax of your ping call slightly).

#!/usr/bin/perl

use strict;
use warnings;

my $command = 'ping -c 5 google.es';

my $variable;
open my $command_pipe, "-|", $command or die "Pipe from $command failed: $!";
while (<$command_pipe>) {
    print  $_;
    $variable .= $_;
}

print "Loop finished:\n$variable\n";

If it's not working for you, you might be Suffering from Buffering. Alternatively, can you give us a complete, self-contained program that demonstrates your problem?

Update: As I suggested above, you're Suffering from Buffering. Did you read the article that I linked to? All you need to do is to switch off buffering on STDOUT.

$|++;

Update 2: To be clear, you need to put that code in test2.pl - that's the program that's doing the buffered prints, so that's where you need to turn buffering off.

edited Oct 17, 2018 at 12:37

answered Oct 17, 2018 at 10:14

Dave Cross

69.5k3 gold badges55 silver badges101 bronze badges

Sign up to request clarification or add additional context in comments.

5 Comments

nck Over a year ago

I just wrote a small program where I show the problem with two perl scripts.

nck Over a year ago

Hi, yes I tried to do that but I could not get it to work. I don't understand where do I have to write that line. Am I supposed to write it before as a flag, inside the while working as a flush, change all $_ for $|++... ?

Dave Cross Over a year ago

Just put it on a line by itself, somewhere near the top of test.pl - perhaps just after the use lines.

nck Over a year ago

Thanks. I just tried writing it in the test2.pl, (the script being called) and it worked. But writing in it in test.pl (the main script) it does not work.

Dave Cross Over a year ago

@nck: Sorry, yes, you're right. It's test2.pl's copy of STDOUT that is doing the buffering, so that's the one you need to change. That was a typo in my comment.

Collectives™ on Stack Overflow

Call system command from perl script printing the output AND storing it into a variable

1 Answer 1

5 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

5 Comments

Your Answer

Sign up or log in

Post as a guest

Related